// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  8.00, 7.00, 2.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;


#declare cor_Amarela = <1, 0.8, 0.1>;

#declare tinta_Azul = 
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta1 = 
  texture {
    pigment { color rgb < 0.30, 0.50, 0.20 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Verde = 
  texture {
    pigment { color rgb < 0.00, 1.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Vermelha = 
  texture {
    pigment { color rgb < 1.00, 0.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare andar =
  box {
    <-3.2,-2.00,0.00>,
    <4.00,2.00,0.80>
    rotate 80*z
    texture { tinta1 }
  }

#declare janela_redonda =
  cylinder {
    < 3.5, -2.05, 0.4 >,
    < 3.5, 2.05, 0.4 >,
    0.2
    texture { tinta_Azul }
  }

#declare janela_quadrada =
  box {
    <3.30,-2.05,0.20>,
    <3.70,2.05,0.60>
    texture { tinta_Azul }
  }

#declare frente =
  box {
    <3.70,-1.00,-1.00>,
    <4.50,1.00,4.00>
    rotate 80*z
    texture { tinta1 }
  }

#declare porta =
  box {
    <3.50,-0.25,0.00>,
    <3.80,0.25,0.80>
    rotate 80*z
    texture { tinta_Verde }
  }

plane { z,-1.5
  texture{
    pigment { checker <0,0,0>, <1,1,1> }
    finish { ambient 0.1 diffuse 0.9 }
    scale 5
  }  
}

// Aqui está a cena, finalmente:

#declare gerador = seed(99999);

#declare predio = 
  union{
  difference{
    union {
      #declare i = 0;
      #while (i < 4)
        object{ andar translate<0,0,0.8*i>}
        #declare j = 0;

          #while (j < 13)
            #if (rand(gerador)>=0.5)
              object{ janela_redonda translate<-0.5*j,0,0.8*i> rotate 80*z} 
            #else
              object{ janela_quadrada translate<-0.5*j,0,0.8*i> rotate 80*z}
            #end
            #declare j = j + 1;
          #end
        
        #declare i = i + 1;
      #end
    }
    object {frente}
  }
  object {porta}
  }

union{
  object{ predio translate<0,0,-1.5>}
  //object{ janelas translate<0,0,-1.5>}
  //object {andar translate<0,0,-1.5>}
  //object {janela_redonda translate<0,0,-1.5>}
}