// Last edited on 2005-01-06 02:08:13 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A =
  texture {
    pigment { color rgb < 0.75, 0.75, 0.75 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.2 }
  }

#declare transp = <0.8,0.8,0.8>;
#declare vidro =
  texture {
    pigment { color transp filter 0.8 }
    finish { 
      diffuse 0.05 
      specular 0.3 roughness 0.001 
      ambient 0.05
      reflection 0.10
    }
  }

#declare janela =
  box {
    <10.501,-1,1>
    <10.500, 1,2>
    texture { vidro }
  }

#declare porta =
  box {
    <10.501,-1,0>
    <10.500, 1,2.3>
  }

#declare n_andares = 6;
#declare R = seed(647296);
#declare topo =
  union {
  box {
    < 2.5, 2.5,n_andares*3>
    <-2.5,-2.5,n_andares*3+3>
    texture { tinta_A }
  }
  object { janela translate <-8,0,n_andares*3> rotate 180*z}
  object { porta  translate <-8,0,n_andares*3>}
  translate <(rand(R)*21-10.5),(rand(R)*21-10.5),0>
}

union {
union {
  #declare andar = 0;
  #while (andar<n_andares)
    object { union {
            box {
         < 10.5, 10.5,0>
         <-10.5,-10.5,3>
         texture { tinta_A }
            }
            #declare c_janela = 0;
            #while (c_janela<4)
                 #declare R1 = 6*rand(R)-3;
         object { union {
                       #declare j = -3;
                       #while (j<=3)
          #if ((andar = 0) & (j = int(R1)))
                             object { porta
                                         translate<0,2.8*j,0>}
         #else
                             object { janela
                                         translate<0,2.8*j,0>}
         #end
                            #declare j = j+1;
                            #end
                         }
                         rotate c_janela*90*z}
          #declare c_janela = c_janela+1;
        #end
        }
             translate<0,0,3*andar>}
  #declare andar = andar+1;
  #end
  object { topo }
}
 translate <0,0,-8>
}

#include "camlight.inc"
camlight(<0,0,0>,<40,20,10>,1.00,z,1.0)