// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

#include "colors.inc"

// ======================================================================
// CÂMERA 

camera {
  location  <5, -5, 40.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
 // sky       z                      // Qual direção é "para cima"?
  look_at   <  5.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
  rotate 30*y
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < -30.0, 30.0, -30.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

#declare amarelo = 
  texture {
    pigment { color rgb < 1.00, 1.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }  
  
#declare azulclaro = 
  texture {
    pigment { color rgb < 0.00, 1.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  

#declare dedos =
union{
cylinder{<0,-1,0>,<2.5,-1,0>,0.25
pigment { Blue }
}  
cylinder{<0,-0.5,0>,<2.5,-0.5,0>,0.25
pigment { Red }
}  
cylinder{<0,0,0>,<2.5,0,0>,0.25
pigment { Magenta }
}  
cylinder{<0,0.5,0>,<2.5,0.5,0>,0.25
pigment { Yellow }
}  
cylinder{<0,1,0>,<2.5,1,0>,0.25
pigment { Green }
}  
}

    
#declare mao=
union{
  object {dedos
        rotate -60*y*clock       
        translate <3,0,0>
  }
  box{
    <0,1.25,0.5>,
    <3,-1.25,-0.5>
    pigment { Magenta }
  }
}

#declare antebraco=
union{
  object{mao
         rotate -70*x*clock
         rotate 50*z*clock
         translate <8,0,0>
  }
  cylinder{<0,0,0>,<8,0,0>,1.25
           pigment {Blue}
  }
}

#declare braco=
union{
  object{antebraco
         rotate -40*z*clock
         translate <0.5,-8,0>
  }
  cylinder{<0,-8.5,0>,<0,0,0>,1.5
           pigment {Green}
  }
}

// ----------------------------------------

plane {
  y, -20
  pigment { color rgb <0.7,0.5,0.3> }
}


object{braco
rotate 70*z*clock
}