// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  < 0, 25, 4 >  // Posição do observador.
  right     -1*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < -50.0, -30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.5 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare tempo = clock;

#declare palma =
  cylinder {
    <0,0,-0.5>,
    <0,0,0.5>,
    1
    texture { tinta_A }
  }
  
#declare dedo = 
  cylinder {
    <0,0,0>,
    <2,0,0>
    0.25
    texture { tinta_A }
  }
  
#declare dedao = 
  cylinder {
    <0,0,0>,
    <0,1.2,0>
    0.25
    texture { tinta_A }
  }
    
#declare mao =
  union {
    object {palma}
    object { dedo rotate tempo*50*y translate <0.9,0,0> rotate -10*z}
    object { dedo rotate -tempo*50*y translate <0.9,0,0> rotate 25*z }
    object { dedao translate <0,0.9,0> }
  }

#declare antebraco =
  union {
    cylinder {
      < 0, 0, 0 >,
      < 6, 0, 0 >,
      1
      texture { tinta_B }
    }
    #if (tempo < 0.5 )
      object { mao rotate 90*x rotate (-tempo*100+50)*y translate <6,0,0>}
    #else
      object { mao rotate 90*x rotate (tempo*100-50)*y translate <6,0,0>}
    #end
  }
  
#declare braco = 
  union {
    cylinder {
      <0,0,0>,
      <0,0,-6>,
      1
      texture { tinta_B }
    }
    sphere {
      <0,0,-6.5>,
      1
      texture { tinta_A }
    }
    object {antebraco rotate -tempo*30*y translate <0,0,-6.5> }
  }

  
 
 // Aqui está a cena, finalmente:
 
  object {braco rotate -tempo*100*y translate <-6,0,0>}