// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tinta_A =
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta_A1 =
  texture {
    pigment { color rgb < 0.5, 0.5, 5 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B =
  texture {
    pigment { color rgb < 1, 0.8, 0 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta_C =
  texture {
    pigment { color rgb < 2, 0.5, 0.5 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta_D =
  texture {
    pigment { color rgb < 0.5, 1, 0.5 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare alfa = -15;
#declare beta = -30;
#declare gama = -15;
#declare teta1 = -30;
#declare teta2 = 30;
#declare tt = clock;

#declare dedo1 =
 cylinder{<-0.3,0,0>,<2.7,0,0>,0.3 texture{tinta_A}}

#declare dedo2 =
 cylinder{<-0.3,0,0>,<2.7,0,0>,0.3 texture{tinta_A}}

#declare mao =
 union{
  box{<-0.3,-1,-0.5>,<1.7,1,0.5> texture{tinta_B}}
  object{dedo1 rotate teta1*y*tt translate <2,-0.7,0>}
  object{dedo2 rotate teta2*y*tt translate <2,0.7,0>}
 }

#declare antebraco =
 union{
  cylinder{<-0.3,0,0>,<7.7,0,0>,1 texture{tinta_C}}
  object{mao rotate gama*y*tt translate <8,0,0>}
}

#declare braco =
 union{
  cone{<-0.3,0,0>,2,<8.7,0,0>,1 texture{tinta_D}}
  object{antebraco rotate beta*y*tt translate <9,0,0>}
 }

object{braco rotate alfa*y*tt}

plane {z,0
 texture{
  pigment{ checker <0.5,0.2,0.1>, <0.3,0.3,0.3>}
  finish{ambient 0.2 diffuse 0.5}
  scale 2
  }
 translate <0,0,-4>
}

#include "camlight.inc"
camlight(<0,0,0>,<35,35,20>,1.00,z,1.0)