// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  < 12.00, 10, 3 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.5*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   < 5, 0, 1 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_Cinza = 
  texture {
    pigment { color < 0.5, 0.5, 0.5 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Cinza_Claro = 
  texture {
    pigment { color < 0.9, 0.9, 0.9 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
  
#declare tinta_Vermelha = 
  texture {
    pigment { color < 0.9, 0.1, 0.1 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare tinta_Marrom = 
  texture {
    pigment { color < 0.5, 0.1, 0.1 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare c=clock;  
    
#declare dedo = 
  difference {
    cylinder {
      < 0, 0, 0 >,
      < 0, 0.3, 0 >,
      0.5
      texture {tinta_Vermelha}
    }
    cylinder {
      < 0, -0.1, 0 >,
      < 0, 0.4, 0 >,
      0.3
      texture {tinta_Vermelha}
    }
    box { <0,0,0> <1,1,1> translate <-0.5,-0.1,0> }
    rotate y*c*45
  }

#declare mao = 
  union {
    cylinder{ <0,0,0>, <0.5,0,0>, 0.3 texture{tinta_Vermelha} }
    object{dedo translate <0.9,-0.15,0>}
    object{dedo rotate x*180 translate <0.9,0.15,0>}
    rotate x*c*220
  }

#declare antebraco =
  union {
    cylinder {
      < 0, 0, 0 >,
      < 3, 0, 0 >,
      0.4
      texture {tinta_Vermelha}
    }
    object{mao translate <3,0,0>}
    rotate y*120*c
  }  
  
#declare braco =
  union {
    cylinder {
      < 0, 0, 0 >,
      < 5, 0, 0 >,
      0.5
      texture {tinta_Vermelha}
    }
    object{antebraco translate <5,0,0>}
    rotate y*-45*c
  }  
  

#declare ombro = 
  union {
    cylinder {
      < 0, 0, 0 >,
      < 0, -2, 0 >,
      0.7
      texture {tinta_Vermelha}
    }
    object{braco}
  }
    
  object{ombro}