// LAB DO DIA 09/11
// PATRICIA FARAH CARRIAO

// ======================================================================
// CÂMERA 

camera {
  location  <  20.00, 0.00, 0.00 >  // Posição do observador.
//location  <  0.00, 0.00, 8.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 5.00, 5.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < -50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.3 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 


// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare verde = 
  texture {
    pigment { color rgb < 0, 1, 0 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare azul = 
 texture {
    pigment { color rgb < 0.30, 0.40, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }


#declare tempo=clock;

#if (tempo<0.5)
	#declare a= 80*clock;
	#declare b= 80*clock;	
	#declare c= -80*clock;
	#declare d= 80*clock;
	#declare e= 80*clock;
#else
	#declare a= -80*clock+80;
	#declare b= -80*clock+80;	
	#declare c= 80*clock-80;
	#declare d= -80*clock+80;
	#declare e= -80*clock+80;
#end


#declare mao = 
	union {
		box { <-0.2,0,-0.5>, <0.2,1.5,0.5>  texture {azul}}
		cylinder { <0,1,0.5>, <0,1,1> 0.2 texture {azul}}
		cylinder { <0,1.5,0.3>, <0,2.2,0.3> 0.1 texture {azul}}
		cylinder { <0,1.5,0.1>, <0,2.2,0.1> 0.1 texture {azul}}
		cylinder { <0,1.5,-0.1>, <0,2.2,-0.1> 0.1 texture {azul}}
		cylinder { <0,1.5,-0.3>, <0,2.2,-0.3> 0.1 texture {azul}}

	}
#declare b1 = 
	union { 
		cylinder { <0,0,0>, <0,3,0> 0.5 texture {verde}}
		object {mao rotate a*x translate<0,3,0> }
		}	

#declare b2 = 
	union { 
		cylinder { <0,0,0>, <0,3,0> 0.5 texture {azul}}
		object {b1 rotate b*x translate<0,3,0> }
		}	

#declare b3 = 
	union { 
		cylinder { <0,0,0>, <0,3,0> 0.5 texture {verde}}
		object {b2 rotate c*x translate<0,3,0> }
		}	

#declare b4 = 
	union { 
		cylinder { <0,0,0>, <0,3,0> 0.5 texture {azul}}
		object {b3 rotate d*x translate<0,3,0> }
		}	

object {b4 rotate e*x}