// Last edited on 2005-01-05 23:31:37 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tinta_cinza_escuro =
  texture {
    pigment { color rgb < 0.30, 0.30, 0.30 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta_eixo =
  texture {
    pigment { color rgb < 0.90, 0.10, 0.50 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare comp_regua = 50;
#declare thick_regua = 0.5;
#declare tinta_regua =
  texture {
    pigment { color rgb < 0.40, 0.20, 0.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare regua =
  union {
    cylinder {
      <0,0,0>
      <comp_regua, 0, 0>
      thick_regua
      texture { tinta_regua }
    }

    cylinder {
      <0,0,0>
      <0, comp_regua, 0>
      thick_regua
      texture { tinta_regua }
    }
    cylinder {
      <0,0,0>
      <0, 0, comp_regua>
      thick_regua
      texture { tinta_regua }
    }

  }

#declare angulo_mordida = 30;

#declare angulo_garra = 90;

#declare angulo_braco = 60;

#declare angulo_antebraco = 120;

#declare garra =
  union {
    cylinder {
      <-0.50,0,0.50>
      <5.50,0,0.50>
      1
      texture { tinta_eixo }
    }
    box {
      <0,0,0>
      <5,-5,1>
      texture { tinta_cinza_escuro }
    }
    cylinder {
      <-0.50,-5.00,0.50>
      <5.50,-5.00,0.50>
      2
      texture { tinta_eixo }
    }
    box {
      <0,0,0>
      <5,10,1>
      texture { tinta_cinza_escuro }
      translate 0.50*z
      rotate (angulo_mordida - (clock * angulo_mordida))*x
    }
    box {
      <0,0,0>
      <5,10,1>
      texture { tinta_cinza_escuro }
      translate -0.50*z
      rotate -(angulo_mordida - (clock * angulo_mordida))*x
    }
    translate <-2.50,5.00,-0.50>

  }

#declare tam_braco = 20;
#declare raio_braco = 1.50;

#declare braco =
  union {
    cylinder {
      <0,0,0>
      <0,tam_braco,0>
      raio_braco
      texture { tinta_cinza_escuro }

    }
  }

#declare tam_pino = 5;
#declare raio_pino = 3;

#declare pino =
  union {
    cylinder {
      <0,0,0>
      <0,0,tam_pino>
      raio_pino
      texture { tinta_eixo }
      translate <0,0, -(tam_pino/2)>
    }
  }

union {
  union {
    object {
      garra
      rotate (angulo_garra - (clock * angulo_garra))*x
      translate <0,tam_braco,0>
    }
    object {
      braco
    }
    object {
      pino
    }
    rotate -(angulo_antebraco - (clock * angulo_antebraco))*z
    translate <0,tam_braco,0>
  }
  union {
    object {
      braco
    }
    object {
      pino
    }
  }
  rotate (angulo_braco - (clock * angulo_braco))*z
}

#include "camlight.inc"
camlight(<0.00,30.00,0.00>,<42.00,12.00,42.00>,1.00,z,1.0)