//Rafael Henrique Castanheira de Souza, ra017134
//laboratorio : A longa mao da justica

// ======================================================================
// CÂMERA 

camera {
  location  < 9.00, 4.00, 1.50 >       // Posição do observador.
  right     -1.00*x              	  // Largura RELATIVA da imagem.
  up         0.50*y                 	  // Altura RELATIVA da imagem.      
  sky       z                             // Qual direção é "para cima"?
  look_at   <  0.00, 2.50, 2.00>          // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < 50.0, 30.0, 50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < -50.0, -40.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.80, 0.80, 1.00>  }



#declare preto = 
  texture {
    pigment { color rgb < 0.00, 0.00, 0.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.015 ambient 0.4 }
  }


#declare verde = 
texture {
    pigment { color rgb < 0.20, 0.80, 0.20 > }
    finish { diffuse 0.5 specular 0.0 roughness 0.05 ambient 0.1 }
  }


#declare azul = 
texture {
    pigment { color rgb < 0.70, 0.70, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.05 ambient 0.1 }
  }


#declare branco = 
texture {
    pigment { color rgb < 1.00, 1.00, 1.00 > }
    finish { diffuse 0.7 specular 0.3 roughness 0.00005 ambient 0.1 }
  }



#declare cinza = 
texture {
    pigment { color rgb < 0.70, 0.70, 0.70 > }
    finish { diffuse 0.6 specular 0.4 roughness 0.5 ambient 0.1 }
  }

#declare amarelo = 
texture {
    pigment { color rgb < 1.0,1.00, 0.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }


#declare fundo =
  plane{<0,0,1>, 0
    texture{       
      pigment {checker <0.80, 0.80, 0.00>,<1.00, 1.00,0.00> }
      finish  {ambient 0.1 diffuse 0.9 }
      //scale 0.5
  }
}


#declare dedo =
  cylinder{
    <0.00,0.00,0.00>,
    <0.00,0.50,0.00>,
    0.05
    texture{azul}
  }

#declare mao =
  union{
    sphere{
      <0.00,0.00,0.00>,
      0.2
      texture{verde}
    }
    object{dedo scale 0.8 rotate 90*x rotate (clock)*120*y translate 0.1*z}
    object{dedo rotate -(clock)*120*z translate <0.00,0.20,-0.10>}
    object{dedo rotate -(clock)*120*z translate <0.00,0.20, 0.10>}
  }

#declare antebraco =
  union{
    cylinder{
      <0.00,0.00,0.00>,
      <0.00,2.00,0.00>,
      0.1
      texture{azul}
    }
    sphere{
      <0.00,0.00,0.00>,
      0.15
      texture{verde}    
    }
    //o valor do angulo deveria ser 10, mas quase nao aparecia
    object{mao rotate 30*(1-clock)*x translate 2*y}
  
 }

#declare braco =
  union{
    cylinder{
      <0.00,0.00,0.00>,
      <0.00,2.00,0.00>,
      0.1
      texture{azul}
    }
    object{antebraco rotate 30*(1-clock)*x translate 2*y}
    
  }   
#declare ombro =
  union{
    difference{
      sphere{
        <0.00,0.00,0.00>,
        0.40
        texture{preto}
      }
      box{
        <-0.50,-0.50,0.00>
        < 0.50, 0.50,-0.50>
        texture{preto}
      }
    }
    object{braco rotate 45*(1-clock)*x translate <0.00,0.10,0.10>}
  }

sky_sphere{
  pigment {color rgb <1,1,1>}
  scale 2
  translate -1
}


union{
  object{ombro}
  object{fundo}
}