// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <20, 50, 12.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
//  look_at   <  0.00, 8.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

//light_source {
//  10 * < -50.0, -10.0, +10.0 >             // Posição da lâmpada.
//  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
//}

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;


#declare cor_Amarela = <1, 0.8, 0.1>;

#declare tinta_Azul = 
  texture {
    pigment { color rgb < 0.00, 0.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Verde = 
  texture {
    pigment { color rgb < 0.00, 1.00, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_Vermelha = 
  texture {
    pigment { color rgb < 1.00, 0.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

//plane { z,0
//  texture{
//    pigment { color rgb < 0.60, 0.30, 0.10 > }
//    finish { ambient 0.1 diffuse 0.9 }
//    scale 5
//  }  
//}

#if (clock<0.25)
  #declare A = -120*clock;
  #declare B = 180*clock;
  #declare C = 120*clock;
  #declare D = -120*clock;
  #declare E = 180*clock;
  #declare F = 0;
#else
  #if (clock<0.5)
    #declare A = -30;
    #declare B = 45;
    #declare C = 30;
    #declare D = -30;
    #declare E = 180*clock;
    #declare F = 180*clock-45;
  #else
    #if (clock<0.75)
      #declare A = -30;
      #declare B = 45;
      #declare C = 30;
      #declare D = -30;
      #declare E = -180*clock+180;
      #declare F = -180*clock+135;
    #else
      #declare A = 120*clock-120;
      #declare B = -180*clock+180;
      #declare C = -120*clock+120;
      #declare D = 120*clock-120;
      #declare E = -180*clock+180;
      #declare F = 0;
    #end
  #end
#end


#declare mao=
  box{<-1,0,-1>, <1,2,1> texture{tinta_Vermelha}}

#declare braco1=
  union{
    object {mao rotate A*x translate <0,3,0> }
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Verde}}
  }

#declare braco2=
  union{
    object {braco1 rotate B*z translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Azul}}
  }

#declare braco3=
  union{
    object {braco2 rotate C*z translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Verde}}
  }

#declare braco4=
  union{
    object {braco3 rotate D*x translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Azul}}
  }

#declare braco11=
  union{
    object {mao rotate A*x translate <0,3,0> }
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Verde}}
  }

#declare braco22=
  union{
    object {braco11 rotate -B*z translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Azul}}
  }

#declare braco33=
  union{
    object {braco22 rotate -C*z translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Verde}}
  }

#declare braco44=
  union{
    object {braco33 rotate D*x translate <0,3,0> }    
    cylinder{<0,0,0>, <0,3,0>, 0.5 texture{tinta_Azul}}
  }

#declare caixa = box { <2.8,6,0>,<-2.8,9,3> texture{tinta_Azul}}

union {
  cylinder{<9.3,0,0>, <-9.3,0,0>, 0.5 texture{tinta_Vermelha}}
  box{<4.5,3,-5>,<-4.5,-3,5> texture{tinta_Vermelha}}

  object {caixa rotate F*x translate<0,0,3.5>}
  object {braco4 translate <9,0,0> rotate E*x}
  object {braco44 translate <-9,0,0> rotate E*x}
}