// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

#include "colors.inc"

camera {
  location  <  6.00, -20.00, 10.00 >  // Posição do observador.
  right     -1.00*x                // Largura RELATIVA da imagem.
  up        0.75*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  8.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < 0.0, 0.0, +20.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, -4.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  < 5, 0, -4 >             // Posição da lâmpada.
  color rgb < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  < 0, -12.75, -5 >             // Posição da lâmpada.
  color rgb 0.4 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  < 20, -12.75, -40 >             // Posição da lâmpada.
  color rgb 0.5 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_cinza = 
  texture {
    pigment { color rgb < 0.85, 0.85, 0.85 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.05 ambient 0.1 }
  }

#declare Glass = 
  texture {
    pigment { White filter 1 }
    finish { 
	diffuse 0.25 
	specular 0.2
	roughness 0.001 
	ambient 0.1 
	reflection 0.25
	}
  }

#declare DarkGlass = 
  texture {
    pigment { White filter 0.5 }
    finish { 
	diffuse 0.25 
	specular 0.2
	roughness 0.001 
	ambient 0.1 
	reflection 0.25
	}
  }
#declare ferro = 
  texture {
    pigment { color rgbf < 0.60, 0.40, 0.40, 0.1 > }
    finish { diffuse 0.6 specular 0.7 roughness 0.005 ambient 0.1 }
  }
  
#declare aco = 
  texture {
    pigment { color rgbf < 0.70, 0.70, 0.90, 0.1 > }
    finish { diffuse 0.5 specular 0.8 roughness 0.005 ambient 0.3 }
  }

#declare madeira = 
  texture {
    pigment { color Brown }
    finish { diffuse 0.25 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare alpha1 = 0;
#declare alpha2 = 90;
#declare alpha3 = 0;

#declare beta2 = 0;

#if (clock<=0.2) 
	#declare alpha1 = -5*clock*90;
	#declare alpha2 = 90;
	#declare alpha3 = 0;

	#declare beta2 = 0;
#else
 #if (clock<=0.4) 
	#declare alpha1 = -90+(clock-0.2)*5*90;
	#declare alpha2 = 90-(clock-0.2)*5*90;
	#declare alpha3 = 0;

	#declare beta2 = 0;
 #else
  #if (clock<=0.6)
	#declare alpha1 = 0;
	#declare alpha3 = 0;
	#declare alpha2 = 0;


	#declare beta2 = -(clock-0.4)*5*19.5;
  #else
   #if (clock<=0.8)
	#declare alpha1 = -(clock-0.6)*5*80;
	#declare alpha2 = 0;//-(clock-0.6)*5*60;
	#declare alpha3 = alpha1;

	#declare beta2 = -19.5;
   #else
    #if (clock<=0.9)
	#declare alpha1 = -80+(clock-0.8)*10*80;
	#declare alpha2 = 0;//-60+(clock-0.8)*10*60;
	#declare alpha3 = alpha1;

	#declare beta2 = -19.5;
    #else
	#declare alpha1 = 0;
	#declare alpha2 = 0;
	#declare alpha3 = 0;

	#declare beta2 = -19.5;
    #end
   #end
  #end
 #end
#end

#declare objeto = 
difference {
	cylinder {
		<0,0,-1>,
		<0,0,2>,
		1
		texture{ DarkGlass }
		translate 6*x
		rotate alpha3*y
		translate 2.4*x
//		rotate alpha3*y
		#if (clock>=0.86) 
			translate -(clock-0.85)*10*10*z
		#end
	}	
}

#declare faca = 
 union {
   cone {
	<0,0,0>, 0.4
	<3,0,0>, 0.01
	texture{ aco }  
	scale <1,0.4,1>
   }
 }

#declare barra1 = 
 union {
   cylinder { 
	<0,0,0>,
	<3,0,0>,
	0.4
	texture{ ferro }  
   }
   sphere {
	<0,0,0>,
	0.4
	texture{ ferro }
   }
   sphere {
	<3,0,0>,
	0.4
	texture{ ferro }
   }
   object { 
	faca
	#if (clock<=0.4)
		translate 7.5*clock*x
	#else
		translate 3*x
	#end	
   }
 }

#declare barra2 = 
 union {
   cylinder { 
	<0,0,0>,
	<3,0,0>,
	0.4
	texture{ ferro }  
   }
   sphere {
	<0,0,0>,
	0.4
	texture{ ferro }
   }
   object { 
	barra1 
	rotate alpha1*y
	translate 3*x
   }
 }

#declare braco =
	object { 
		barra2 
		rotate alpha2*y
		rotate beta2*z
	}

#declare robo = 
union {
	object {
		braco
		translate 4*y
	}
	object {
		braco
		translate 4*y
		scale -1*y
	}
	cylinder {
		<0,0,-5>,
		<0,0,3>,
		4
		scale <0.4,1,1>
		texture { ferro }
	}
	cylinder {
		<0,0,3>,
		<0,0,3.5>,
		1
		texture { ferro }
	}
	sphere {
		<0,0,5>,
		1.5
		texture { ferro }
	}
}

// Aqui está a cena, finalmente:
union {
	object{ robo }
	object{ 
		objeto 
	}
//	plane {
//		<0,0,1>,-5
//		texture { aco }
//	}
}