#include "colors.inc"
#include "stones.inc"
#include "metals.inc"
#include "woods.inc"

// Exemplo de arquivo de descricao de cena para POV-ray

// ======================================================================
// CÂMERA 

camera {
  location  < 6.00, -15.00, 4.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, -2.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.


// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 2.50, 2.50, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  5 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 2.50, 2.00, 1.00 >   // Intensidade e corda luz.
} 


// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }


#declare plano = 
	plane {
	z,-10
	texture {
		T_Wood16
	}
	}

#macro ramo(n,tx1,tx2)
	union {
	  #if (n>0)
		sphere{ 
		  <0,0,0>,1
		  texture { tx1 }
		}
		#if (n>1)		
		  sphere{ 
		    <0,n*n,n*n>,1
		    texture { tx1 }
		  }
		  sphere{ 
		    <0,0,n*n>,1
		    texture { tx1 }
		  }
		cylinder {
		  <0,0,0>,<0,n*n,n*n>,0.5
		  texture { tx2 }
		}
		cylinder {
		  <0,0,0>,<0,0,n*n>,0.5
		  texture { tx2 }
		}
		#end
		 
		  object { ramo(n-1,tx1,tx2) translate <0,n*n,n*n> }
		  object { ramo(n-1,tx1,tx2) translate <0,0,n*n> }
		
	  #end
	}
#end

#declare tinta1 = 
  texture {
    pigment { Red }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta2 = 
  texture {
    pigment { Green }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }


// Aqui está a cena, finalmente:

#declare arvore = 
union {
	#declare prof = 4;
	object { ramo(prof,T_Brass_3C,tinta1) scale <1,1,-1> }
	object { ramo(prof,T_Brass_3C,tinta1) scale <1,1,-1> rotate 90*z }
	object { ramo(prof,T_Brass_3C,tinta1) scale <1,-1,-1>}
	object { ramo(prof,T_Brass_3C,tinta1) scale <1,-1,-1> rotate 90*z }

	union {
	  object { ramo(prof,T_Brass_3C,tinta2) scale <1,1,-1> }
	  object { ramo(prof,T_Brass_3C,tinta2) scale <1,1,-1> rotate 90*z }
	  object { ramo(prof,T_Brass_3C,tinta2) scale <1,-1,-1>}
	  object { ramo(prof,T_Brass_3C,tinta2) scale <1,-1,-1> rotate 90*z }
	  rotate 45*z
	}

} 

object { plano }
object { arvore scale <0.2,0.2,0.2> }