// Last edited on 2005-01-06 00:14:30 by stolfi
// Processed by remove-cam-lights
#include "colors.inc"
#include "stones.inc"
#include "metals.inc"
#include "woods.inc"

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare plano =
 plane {
 z,-10
 texture {
  T_Wood16
 }
 }

#macro ramo(n,tx1,tx2)
 union {
   #if (n>0)
  sphere{
    <0,0,0>,1
    texture { tx1 }
  }
  #if (n>1)
    sphere{
      <0,n*n,n*n>,1
      texture { tx1 }
    }
    sphere{
      <0,0,n*n>,1
      texture { tx1 }
    }
  cylinder {
    <0,0,0>,<0,n*n,n*n>,0.5
    texture { tx2 }
  }
  cylinder {
    <0,0,0>,<0,0,n*n>,0.5
    texture { tx2 }
  }
  #end

    object { ramo(n-1,tx1,tx2) translate <0,n*n,n*n> }
    object { ramo(n-1,tx1,tx2) translate <0,0,n*n> }

   #end
 }
#end

#declare tinta1 =
  texture {
    pigment { Red }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tinta2 =
  texture {
    pigment { Green }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare arvore =
union {
 #declare prof = 4;
 object { ramo(prof,T_Brass_3C,tinta1) scale <1,1,-1> }
 object { ramo(prof,T_Brass_3C,tinta1) scale <1,1,-1> rotate 90*z }
 object { ramo(prof,T_Brass_3C,tinta1) scale <1,-1,-1>}
 object { ramo(prof,T_Brass_3C,tinta1) scale <1,-1,-1> rotate 90*z }

 union {
   object { ramo(prof,T_Brass_3C,tinta2) scale <1,1,-1> }
   object { ramo(prof,T_Brass_3C,tinta2) scale <1,1,-1> rotate 90*z }
   object { ramo(prof,T_Brass_3C,tinta2) scale <1,-1,-1>}
   object { ramo(prof,T_Brass_3C,tinta2) scale <1,-1,-1> rotate 90*z }
   rotate 45*z
 }

}

object { plano }
object { arvore scale <0.2,0.2,0.2> }

#include "camlight.inc"
camlight(<0,0,-2>,<6,-15,6>,1.00,z,1.0)