// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  30.00, 4, 8.00 >  // Posição do observador.
  right     -0.75*x                // Largura RELATIVA da imagem.
  up        1.00*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, -6.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare i = 0;
#macro arvore(n)
	union {
		sphere { <0,0,0>, 0.5 texture {tinta_A} }
		cylinder { <0, 2*n, -2*n>
			   <0, 0, 0>
			   0.1
			   texture {tinta_B} }
		cylinder { <0, -2*n, -2*n>
			   <0, 0, 0>
			   0.1
			texture {tinta_B} }
		cylinder { <2*n, 0, -2*n>
			   <0, 0, 0>
			   0.1
			texture {tinta_B} }
		
		#if (1<n) 
			object { arvore(n-1) translate <0,2*n, -2*n> }
			object { arvore(n-1) translate <0, -2*n, -2*n> }
			object { arvore(n-1) translate <2*n, 0, -2*n> }
		#end
	}
#end




object { arvore(5) scale 0.5 translate <0,0,6>}