// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

#include "colors.inc"

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;
#declare amarelo = <1,.8,.1>;
#declare verde = <0,1,0>;
#declare vermelho = <1,0,0>;

#declare tverde =
    texture {
 finish {
  ambient 0.1 diffuse .1 reflection .25
  specular 1 roughness .001
  }
 pigment { color verde filter 1 }
 }

#declare tinta_A =
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.1 }
  }

#declare tvermelho =
    texture {
 finish {
  ambient 0.1 diffuse .1 reflection .25
  specular 1 roughness .001
  }
 pigment { color vermelho filter 1 }
 }

#declare tx_espelho =
texture {
 pigment { rgb amarelo }
 finish {
 ambient .05 diffuse .05
 reflection amarelo *.50
 specular .20 roughness .05
}
}

#macro noh(d,e,f)
 sphere {
  <d,e,f>,
  .5
  texture {tinta_A}
 }
#end
#macro ligacao(x1,y1,z1,x2,y2,z2)
 cylinder {
  <x1,y1,z1>,
  <x2,y2,z2>,
  0.2
  texture {tvermelho}
  }
#end
#macro arvore (d,e,f,n)
 union {
 #if (n=1)
  object { noh(d,e,f) }
 #else
    #if (mod (n,2)=1)
  #local a1=d-.9*n;
  #local b1=e;
  #local c1=f-.9*n;
  #local a2=d+.9*n;
  #local b2=e;
  #local c2=f-.9*n;
    #else
  #local a1=d;
  #local b1=e-.9*n;
  #local c1=f-.9*n;
  #local a2=d;
  #local b2=e+.9*n;
  #local c2=f-.9*n;
    #end
    object {noh(d,e,f) }
    object {ligacao (d,e,f,a1,b1,c1) }
    object {ligacao (d,e,f,a2,b2,c2)  }
    object {arvore(a1,b1,c1,n-1) }
    object {arvore(a2,b2,c2,n-1) }
 #end
}
#end

object {arvore(0,0,10,5)}

#include "camlight.inc"
camlight(<0,0,0>,<40,-40,0>,1.00,z,1.0)