// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 
camera {
//  location  <-3.00, -0.50, 0.0 >  // Posição do observador.
  location  <-6.00, 10.0, 14.0 >  // Posição do observador.
  right     -2*x                   // Largura RELATIVA da imagem.
  up        1*y                 // Altura RELATIVA da imagem.      
  sky       y                      // Qual direção é "para cima"?
//  look_at   <0.0, 0.00, 0.0 >  // Para onde a câmera está apontando.
  look_at   <-1.0, 0.0, 0.0 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ
light_source {
  < 0.0, 10.0, 6.0 >              // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 


light_source {
  < 4.0, 10.0, 0.0 >              // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 


light_source {
  < -4.0, 10.0, 0.0 >              // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA

background{ color rgb < 0.50, 0.50, 0.70 > }

#declare textura_aviao = 
  texture {
    pigment { rgb <0.6, 0.6, 0.5> }
    finish { diffuse 0.5 roughness 0.01 reflection 0.2 }
  }

#declare textura_asa = 
  texture {
    pigment { rgb <0.7, 0.7, 0.7> }
    finish { diffuse 0.3 reflection 0.5 roughness 0.2 }
  }

#declare chao =
  plane {
    y,
    -40.0
    texture {
      pigment { checker <0.55, 0.55, 0.35>, <0.30, 0.55, 0.30> }
      finish { diffuse 0.4 }
      scale 8
    }
  }

#macro next(border, previous)
  2*border - previous
#end
  
// Asa 1
// z = 3
#declare A11=<0,0.5,3>; #declare A12=<4,0.5,3>; 
#declare A13=<8,0.5,3>; #declare A14=<12,0.5,3>;
// z = 2
#declare A21=<0,2,2>; #declare A22=<4,1.8,2>;
#declare A23=<8,1.6,2>; #declare A24=<12,1.4,2>;
// z = 1
#declare A31=<0,1.2,1>; #declare A32=<4,1.2,1>;
#declare A33=<8,1.2,1>; #declare A34=<12,1.2,1>;
// z = 0
#declare A41=<0,1,0>; #declare A42=<4,1,0>;
#declare A43=<8,1,0>; #declare A44=<12,1,0>;

// Asa 2
// z = 0
#declare B11=A41; #declare B12=A42;
#declare B13=A43; #declare B14=A44;
// z = -1
#declare B21=next(B11,A31); #declare B22=next(B12,A32);
#declare B23=next(B13,A33); #declare B24= next(B14,A34);
// z = -2
#declare B31=<0,0.8,-2>; #declare B32=<4,0.8,-2>;
#declare B33=<8,0.8,-2>; #declare B34=<12,0.8,-2>;
// z = -3
#declare B41=<0,-0.5,-3>; #declare B42=<4,-0.5,-3>;
#declare B43=<8,-0.5,-3>; #declare B44=<12,-0.5,-3>;

// Asa 3 (abaixo da asa 1)
// z = 3
#declare C11=A11; #declare C12=A12; 
#declare C13=A13; #declare C14=A14;
// z = 2
#declare C21=next(C11,A21); #declare C22=next(C12,A22);
#declare C23=next(C13,A23); #declare C24=next(C14,A24);
// z = 1
#declare C31=<0,-1.2,1>; #declare C32=<4,-1.2,1>;
#declare C33=<8,-1.2,1>; #declare C34=<12,-1.2,1>;
// z = 0
#declare C41=<0,-1.1,0>; #declare C42=<4,-1.1,0>;
#declare C43=<8,-1.1,0>; #declare C44=<12,-1.1,0>;

// Asa 4 (abaixo da asa 2)
// z = 0
#declare D11=C41; #declare D12=C42;
#declare D13=C43; #declare D14=C44;
// z = -1
#declare D21=next(D11,C31); #declare D22=next(D12,C32);
#declare D23=next(D13,C33); #declare D24= next(D14,C34);
// z = -2
#declare D31=next(B41, B31); #declare D32=next(B42, B32);
#declare D33=next(B43, B33); #declare D34=next(B44, B34);
// z = -3
#declare D41=B41; #declare D42=B42;
#declare D43=B43; #declare D44=B44;


#declare asa1 = bicubic_patch {
   type 1 flatness 0.001
   u_steps 4 v_steps 4
   uv_vectors
   <0,0> <1,0> <1,1> <0,1>
   A11, A12, A13, A14
   A21, A22, A23, A24
   A31, A32, A33, A34
   A41, A42, A43, A44
   uv_mapping
   texture { textura_asa }
}

#declare asa2 = bicubic_patch {
   type 1 flatness 0.001
   u_steps 4 v_steps 4
   uv_vectors
   <0,0> <1,0> <1,1> <0,1>
   B11, B12, B13, B14
   B21, B22, B23, B24
   B31, B32, B33, B34
   B41, B42, B43, B44
   uv_mapping
   texture { textura_asa }
   no_shadow
}

#declare asa3 = bicubic_patch {
   type 1 flatness 0.001
   u_steps 4 v_steps 4
   uv_vectors
   <0,0> <1,0> <1,1> <0,1>
   C11, C12, C13, C14
   C21, C22, C23, C24
   C31, C32, C33, C34
   C41, C42, C43, C44
   uv_mapping
   texture { textura_asa }
   no_shadow
}

#declare asa4 = bicubic_patch {
   type 1 flatness 0.001
   u_steps 4 v_steps 4
   uv_vectors
   <0,0> <1,0> <1,1> <0,1>
   D11, D12, D13, D14
   D21, D22, D23, D24
   D31, D32, D33, D34
   D41, D42, D43, D44
   uv_mapping
   texture { textura_asa }
   no_shadow
}

#declare asa =
union {
  object { asa1 }
  object { asa2 }
  object { asa3 }
  object { asa4 }
}

union {
  object { asa translate <1,0,0> }
  object { asa translate <1,0,0> scale<-1,1,1> }
  cone {<0,0,7>, 2.0, <0,0,-10>, 1.4 texture { textura_aviao }}
  object { chao }
}