// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2003-09-04 15:25:26 by stolfi

// ======================================================================
// CÂMERA 

camera {
  location  <  10.00, 10.00, 6.00 >  // Posição do observador.
  right     1.00*y               // Largura RELATIVA da imagem.
  up        -0.75*x                   // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source {
  10 * < +50.0, +30.0, +50.0 >              // Posição da lâmpada.
  color rgb 1.2 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source {
  10 * < +50.0, -10.0, +10.0 >             // Posição da lâmpada.
  color rgb 0.8 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// DESCRIÇÃO DA CENA 

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare branco = 
  texture {
    pigment { color rgb < 3.00, 3.00, 3.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare preto = 
  texture {
    pigment { color rgb < 0.00, 0.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare vermelho = 
  texture {
    pigment { color rgb < 2.00, 0.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }
  
#declare verde = 
  texture {
    pigment { color rgb < 0.00, 2.00, 0.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare azul = 
  texture {
    pigment { color rgb < 0.00, 0.00, 2.00 > }
    finish { diffuse 0.5 specular 0.5 roughness 0.005 ambient 0.1 }
  }

#declare eixoX = 
  cylinder {
    < 0.00, 0.00, 0.00 >,
    < 10.00, 0.00, 0.00 >,
    0.05
    texture { vermelho }
  }

#declare eixoY = 
  cylinder {
    < 0.00, 0.00, 0.00 >,
    < 0.00, 10.00, 0.00 >,
    0.05
    texture { verde }
  }

#declare eixoZ = 
  cylinder {
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, 10.00 >,
    0.05
    texture { azul }
  }

#declare eixos_cartesianos =
  union {
    object {eixoX }
    object {eixoY }
    object {eixoZ }
}

#declare caixa = 
  box {
    < -0.50, -0.50, 0.00 >,
    < 0.50, 0.50, -1.00 >
  }

#declare base_tabuleiro = 
  union {
    object {caixa
 	     translate <0.50,0.50,0>
	     texture { preto }
	 }
    object {caixa
 	     translate <-0.50,0.50,0>
	     texture { branco }
	 }
    object {caixa
 	     translate <0.50,-0.50,0>
	     texture { branco }
	 }
    object {caixa
 	     translate <-0.50,-0.50,0>
	     texture { preto }
	 }
}

#declare cone_base_peao = 
  cone {
    <  0.00, 0.00, 0.00 >, 0.25
    <  0.00, 0.00, 1.00 >, 0.00 
    
    texture { azul }
  }  

#declare esfera_cabeca_peao =
  sphere {
    < 0.00, 0.00, 1.00 >, 0.20 
    texture { azul }
  }

#declare peao = 
  union {
    object {cone_base_peao}
    object {esfera_cabeca_peao}
}

#declare cilindro_base_torre = 
  cylinder {
    < 0.00, 0.00, 0.00 >,
    < 0.00, 0.00, 1.00 >,
    0.20
    texture { vermelho }
  }

#declare cilindro_cabeca_torre = 
  cylinder {
    < 0.00, 0.00, 1.00 >,
    < 0.00, 0.00, 1.30 >,
    0.35
    texture { vermelho }
  }

#declare torre = 
  union {
    object {cilindro_base_torre}
    object {cilindro_cabeca_torre}
}

#declare esfera_base_rei =
  sphere {
    < 0.00, 0.00, 0.50 >, 0.50 
    texture { verde }
  }

#declare esfera_cabeca_rei =
  sphere {
    < 0.00, 0.00, 1.30 >, 0.25 
    texture { verde }
  }

#declare cone_coroa_rei = 
  cone {
    <  0.00, 0.00, 1.50 >, 0.40
    <  0.00, 0.00, 1.80 >, 0.00 
    texture { verde }
  }  

#declare rei = 
  union {
    object {esfera_base_rei}
    object {esfera_cabeca_rei}
    object {cone_coroa_rei}
}


// Aqui está a cena, finalmente:


// desenho dos eixos

//object { eixos_cartesianos }


// desenha o tabuleiro sem as pecas

#declare i=0;

#while (i<20)
  #declare j=0;	
  #while (j<20)
    object{ base_tabuleiro
             translate <i*2,j*2,0>
	  }
    object{ base_tabuleiro
             translate <-(i*2),j*2,0>
	  }
    object{ base_tabuleiro
             translate <i*2,-(j*2),0>
	  }
    object{ base_tabuleiro
             translate <-(i*2),-(j*2),0>
	  }
    #declare j=j+1;

  #end

  #declare i=i+1;

#end


//desenha as pecas no tabuleiro de maneira aleatoria

#declare roleta = seed (23554);

#declare i=0;
#while (i<39)

  #declare j=0;	
  #while (j<39)

    #declare aleatorio = rand(roleta);
    
    #if ( aleatorio < 0.30 )
      object{ peao
               translate <i+0.5,j+0.5,0>
	    }
    #else
      #if ( aleatorio < 0.45)
	object{ torre
                 translate <i+0.5,j+0.5,0>
	      }
      #else
	#if (aleatorio < 0.50)
	  object{ rei
                   translate <i+0.5,j+0.5,0>
	        }
	#end
      #end
    #end

    #declare aleatorio = rand(roleta);
    
    #if ( aleatorio < 0.30 )
      object{ peao
               translate <-(i+0.5),j+0.5,0>
	    }
    #else
      #if ( aleatorio < 0.45)
	object{ torre
                 translate <-(i+0.5),j+0.5,0>
	      }
      #else
	#if (aleatorio < 0.5)
	  object{ rei
                   translate <-(i+0.5),j+0.5,0>
	        }
	#end
      #end
    #end

    #declare aleatorio = rand(roleta);
    
    #if ( aleatorio < 0.30 )
      object{ peao
               translate <i+0.5,-(j+0.5),0>
	    }
    #else
      #if ( aleatorio < 0.45)
	object{ torre
                 translate <i+0.5,-(j+0.5),0>
	      }
      #else
	#if (aleatorio < 0.5)
	  object{ rei
                   translate <i+0.5,-(j+0.5),0>
	        }
	#end
      #end
    #end

    
    #declare aleatorio = rand(roleta);
    
    #if ( aleatorio < 0.30 )
      object{ peao
               translate <-(i+0.5),-(j+0.5),0>
	    }
    #else
      #if ( aleatorio < 0.45)
	object{ torre
                 translate <-(i+0.5),-(j+0.5),0>
	      }
      #else
	#if (aleatorio < 0.5)
	  object{ rei
                   translate <-(i+0.5),-(j+0.5),0>
	        }
	#end
      #end
    #end



    #declare j=j+1;

  #end

  #declare i=i+1;

#end