// Last edited on 2007-07-22 23:59:12 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;
#declare roleta = seed(4615);

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.20, 0.20, 0.20 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.2 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 1.00, 1.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.2 }
  }
#declare tinta_C = 
  texture {
    pigment { color rgb < 0.10, 0.30, 1.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.2 }
  }
#declare tinta_D = 
  texture {
    pigment { color rgb < 0.00, 1.00, 1.00 > }
    finish { diffuse 0.8 specular 0.2 roughness 0.005 ambient 0.2 }
  }
  
#declare base_pc = 
  cone {
    <0, 0, 11.5>, 0.1
    <0, 0, 0.8>, 2.0
    texture { tinta_C }
}

#declare meio_pc = 
  cylinder {
    < 0.00, 0.00, 8.00 >,
    < 0.00, 0.00, 1.80 >,
    1.26
    texture { tinta_D }
  }
#declare topo_pc = 
  cylinder {
    < 0.00, 0.00, 10.00 >,
    < 0.00, 0.00, 8.00 >,
    1.86
    texture { tinta_D }
  }
#declare topo_rei = 
 box {
    < -0.50,-0.50, 12.00 >,
    < 0.50, 0.50, 10.00 >
    texture { tinta_A }
}
#declare topo_rainha_peao = 
 sphere {
    < 0.00, 0.00, 11.10 >,
    1.1
    texture { tinta_A }
}

#declare ele_tab_preto = 
 box {
    < -2.50,-2.50, 0.00 >,
    < 2.50, 2.50, 0.80 >
    texture { tinta_A }
}

#declare ele_tab_branco = 
 box {
    < -2.50, 2.50, 0.00 >,
    < 2.50, 7.50, 0.80 >
    texture { tinta_B }
}

#declare j = 0;
#while(j < 20)
 #declare i = 0;
 #while(i < 20)
  union {
   object { ele_tab_preto }
   object { ele_tab_branco }
   union {
    object { ele_tab_preto }
    object { ele_tab_branco } 
    rotate<180,0, 0>
    translate<5, 5, 0.8>
   }
   translate<10*i, 10*j, 0>

  } 
  #declare i = i + 1;
 #end
 #declare j = j + 1;
#end
#declare i = 0;

#declare peao =  
union {
 object {base_pc}
 object {topo_rainha_peao}
}

#declare rei = 
union {
 object {base_pc}
 object {meio_pc}
 object {topo_pc}
 object {topo_rei}
}

#declare rainha = 
union {
 object {base_pc}
 object {meio_pc}
 object {topo_pc}
 object {topo_rainha_peao}
}
#declare posicao_x = int(40*rand(roleta));
#declare posicao_y = int(40*rand(roleta));
union {
object {rei}
translate<posicao_x*5, posicao_y*5, 0>
}

#declare posicao_x = int(40*rand(roleta));
#declare posicao_y = int(40*rand(roleta));
union {
object {rei}
translate<posicao_x*5, posicao_y*5, 0>
}

#declare posicao_x = int(40*rand(roleta));
#declare posicao_y = int(40*rand(roleta));
union {
object {rainha}
translate<posicao_x*5, posicao_y*5, 0>
}

#declare posicao_x = int(40*rand(roleta));
#declare posicao_y = int(40*rand(roleta));
union {
object {rainha}
translate<posicao_x*5, posicao_y*5, 0>
}

#while(i < 40)
 
 #declare posicao_x = int(40*rand(roleta));
 #declare posicao_y = int(40*rand(roleta));
 union{
  object {peao} 
  translate<5*posicao_x, 5*posicao_y, 0>
 }   
 #declare i = i + 1;
#end

// Original camera parameters:
// #local cam_ctr = <100.00,100.00,0.00>
// #local cam_vec = (<0.00,0.00,55.00>-<100.00,100.00,0.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<100.00,100.00,0.00>,<10,10,10>,220.0,z,1.0)