// Last edited on 2007-07-23 10:01:31 by stolfi
// Processed by remove-cam-lights

global_settings { max_trace_level 12 }

#declare tinta_xadrez =
  texture {
    pigment { checker color rgb <0.40,0.50,0.60>, color rgb <0.90,0.95,1.00> }
    finish { ambient 0.6 diffuse 0.4 }
  }

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tinta_amarela = texture {
    pigment { color rgb <1,0.7,0> }
    finish  { diffuse 0.3 specular 0.3 roughness 0.005 ambient 0.2 reflection 0.2}
   }

#declare tinta_verde = texture {
    pigment { color rgb <0,1,0> }
    finish  { diffuse 0.3 specular 0.3 roughness 0.005 ambient 0.2 reflection 0.2}
   }

#declare tinta_prata = texture {
    pigment { color rgb <0.6, 0.6, 0.6> }
    finish  { diffuse 0.3 specular 0.3 roughness 0.005 ambient 0.2 reflection 0.2}
   }

#declare tinta_azul = texture {
    pigment { color rgb <0, 0, 1> }
    finish  { diffuse 0.3 specular 0.3 roughness 0.005 ambient 0.2 reflection 0.2}
   }

#declare tinta_vermelha = texture {
    pigment { color rgb <1, 0, 0> }
    finish  { diffuse 0.3 specular 0.3 roughness 0.005 ambient 0.2 reflection 0.2}
   }

#macro mao()
 sphere{
  <0,0,0>,1.5
  texture {tinta_vermelha}
 }
#end

#macro antebracoETC()
 union{
  cylinder {
   <0,0,0>,
   <0,3,0>,
   0.5
   texture {tinta_prata}
  }
  object{
   mao() translate 3*y
  }
 }
#end

#macro bracoETC(xis, ipsolon)
 union{
  cylinder {
   <0,0,0>,
   <0,3,0>,
   0.6
   texture {tinta_verde}
  }
  object{
   antebracoETC()
   rotate xis*x
   rotate ipsolon*y
   translate 3*y
  }
 }
#end

#macro pernaETC(angulo)
 cylinder {
  <0,0,0>,
  <0,0,-10>
  0.6
  texture{tinta_prata}
  rotate angulo*y
 }
#end

#macro orelha()
 sphere {
  <0,0,0>,0.5
  scale <0.4,0.4,1>
  texture {tinta_amarela}
 }
#end

#macro cabeca()
 union{
  sphere{
   <0,0,0>, 1.5
   scale <1,1,2>
   texture {tinta_prata}
  }
  object {orelha()
   translate <0,0,2.8>
   rotate 15*x
  }
  object {orelha()
   translate <0,0,3.2>
   rotate -15*y
  }
 }
#end

#macro corpo(anguloBracoEsqX, anguloBracoDirX, anguloBracoEsqY, anguloBracoDirY, anguloPernaEsq, anguloPernaDir)
 union{
  cylinder {
   <0,0,0>,
   <0,0,10>,
   2
   texture {tinta_amarela}
  }
  object {
   bracoETC(anguloBracoEsqX, anguloBracoEsqY)
   translate <0,2,10>
  }
  object {
   bracoETC(anguloBracoDirX, anguloBracoDirY)
   translate <0,2,10>
   rotate 180*z
  }

  object{
   cabeca()
   translate <0,0,11>
  }

  object {
   pernaETC(anguloPernaEsq)
   translate <0,1,0>
  }
  object {
   pernaETC(anguloPernaDir)
   translate <0,-1,0>
  }
 }
#end

corpo(-60,60,-40,30,15,45)

// Original camera parameters:
// #local cam_ctr = <0.00,0.00,2.00>
// #local cam_vec = (<30.00,6.00,6.00>-<0.00,0.00,2.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,0.00,2.00>,<10,10,10>,30.0,z,1.0)