// Last edited on 2007-07-23 10:15:54 by stolfi
// Processed by remove-cam-lights

global_settings { max_trace_level 12 }

#declare tinta_xadrez =
  texture {
    pigment { checker color rgb <0.40,0.50,0.60>, color rgb <0.90,0.95,1.00> }
    finish { ambient 0.6 diffuse 0.4 }
  }

background{ color rgb < 0.75, 0.80, 0.85 > }

plane { z,0
  translate -6*z
  texture { tinta_xadrez }
}

#declare azul =
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.5 roughness 0.005 ambient 0.1 }
  }

#declare vermelho =
  texture {
    pigment { color rgb < 1.00, 0.00, 0.00 > }
    finish { diffuse 0.8 ambient 0.2 }
  }

#declare verde =
  texture {
    pigment { color rgb < 0, 1, 0 > }
    finish { diffuse 0.8 ambient 0.2 }
  }

#declare cabeca =
  sphere {
    < 0, 0, 0 >
    0.8
    texture { verde }
  }

#declare olho =
  sphere {
    < 0, 0, 0 >
    0.2
    texture { azul }
  }

#declare boca =
  sphere {
    < 0, 0, 0 >
    0.4
    texture { vermelho }
  }

#macro mao()
  sphere { < 0, -0.2, 0 >, 0.4 }
#end

#macro antebraco(alfa)
  union {
    cylinder { < 0, 0, 0 > , < 0, -2, 0 > , 0.3 }
    object { mao()
      rotate alfa*x
      translate -2*y
    }
  }
#end

#macro braco(beta, alfa)
  union {
    cylinder { < 0, 0, 0 > , < 0, -2, 0 > , 0.3 }
    object { antebraco(alfa)
      rotate beta*x
      translate -2*y
    }
  }
#end

#macro pe()
  box {
    < -0.3, 0, 0 >,
    < 0.3, -0.8, 0.6 >
  }
#end

#macro canela(alfa)
  union {
    cylinder { < 0, 0, 0 > , < 0, -2, 0 > , 0.3 }
    object { pe()
      rotate alfa*x
      translate -2*y
    }
  }
#end

#macro perna(beta, alfa)
  union {
    cylinder { < 0, 0, 0 > , < 0, -2, 0 > , 0.3 }
    object { canela(alfa)
      rotate beta*x
      translate -2*y
    }
  }
#end

#macro corpo(gama, omeg, beta, alfa, gama1, omeg1, beta1, alfa1, gama2, omeg2, beta2, alfa2, gama3, omeg3, beta3, alfa3)
  union {
    box { < -1, -0.5, -2 >, < 1, 0.5, 2 > }
    object { braco(beta, alfa)
      rotate gama*z
      rotate omeg*x
      translate ( 1*x + 1.5*z )
    }
    object { braco(beta1, alfa1)
      scale < -1, 1, 1 >
      rotate gama1*z
      rotate omeg1*x
      translate ( -1*x + 1.5*z )
    }
    object { perna(beta2, alfa2)
      rotate gama2*z
      rotate omeg2*x
      translate ( 0.8*x + -2*z )
    }
    object { perna(beta3, alfa3)
      scale < -1, 1, 1 >
      rotate gama3*z
      rotate omeg3*x
      translate ( -0.8*x + -2*z )
    }
    object { cabeca translate 2.8*z }
    object { olho translate (3*z + -0.5*y + 0.5*x) }
    object { olho translate (3*z + -0.5*y + -0.5*x) }
    object { boca translate (2.6*z + -0.45*y) }
  }
#end

object { corpo(45,45,-90,-45,-45,45,-90,-45,20,80,45,-90,-20,80,45,-90) texture { verde } }

// Original camera parameters:
// #local cam_ctr = <0,0,0>
// #local cam_vec = <8.00,-10.00,1.00>
// #local cam_sky = z

#include "camlight.inc"
camlight(<0,0,0>,<4,-10,3>,15.0,z,1.0)