// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

#declare abertura_pata_frontal_direita = 0;
#declare rotacao_coxa_pata_frontal_direita = 150 - 120*clock;
#if (clock < 0.5)
 #declare rotacao_canela_pata_frontal_direita = 80 - 140*clock;
#end
#if (clock >= 0.5)
 #declare rotacao_canela_pata_frontal_direita = 10 + (clock-0.5)*140;
#end
#declare rotacao_peh_pata_frontal_direita = 0;

#declare abertura_pata_frontal_esquerda = 30;
#declare rotacao_coxa_pata_frontal_esquerda = -4*10*clock*clock +4*10*clock -80;
#declare rotacao_canela_pata_frontal_esquerda = 4*120*clock*clock -4*120*clock + 120;
#declare rotacao_peh_pata_frontal_esquerda = 4*45*clock*clock - 4*45*clock -45;

#declare abertura_pata_traseira_direita = -30;
#declare rotacao_coxa_pata_traseira_direita = 4*120*clock*clock - 4*120*clock + 80;
#declare rotacao_canela_pata_traseira_direita = -4*120*clock*clock + 4*120*clock - 120;
#declare rotacao_peh_pata_traseira_direita = 4*129*clock*clock - 4*129*clock + 39;

#declare abertura_pata_traseira_esquerda = -30;
#declare rotacao_coxa_pata_traseira_esquerda = 4*120*clock*clock - 4*120*clock + 80;
#declare rotacao_canela_pata_traseira_esquerda = -4*120*clock*clock + 4*120*clock - 120;
#declare rotacao_peh_pata_traseira_esquerda = 4*129*clock*clock - 4*129*clock + 39;

#declare posicao_x = 0 + 10*clock;

#if (clock < 0.5)
 #declare posicao_z = 0 + 20*clock;
#end
#if (clock >= 0.5)
 #declare posicao_z = 10 - 20*(clock-0.5);
#end

#declare radioactive = texture {
  pigment { color rgbf <0.8, 1, 0.1, 0.2> }
  finish {
    ambient 0.2
    diffuse 0.2
    specular 0.3 roughness 0.05
  }
}

#declare gold = texture {
  pigment { color rgb <0.8, 0.85, 0.05> }
  finish {
    ambient 0.2
    diffuse 0.3
    specular 0.2  roughness 0.05
    reflection 0.3
  }
}

#declare body =
union {
  sphere { <0, 0, 0>, 4 scale <1, 1, 0.3> }
  sphere { <4.5, 0, 1.4>, 2.5 scale <1, 1, 0.4> }
  sphere { <6, 1.8, 1.4>, 0.5 }
  sphere { <6, -1.8, 1.4>, 0.5 }
}

#declare peh =
union {
  box { <0, 0.6, -0.15>, <2, -0.6, 0.15> }
  cylinder { <2, 0, 0>, <4, 0, 0>, 0.15 }
  sphere { <4, 0, 0>, 0.2 }
  object { union {
    cylinder { <2, 0, 0>, <3.8, 0, 0>, 0.15 }
    sphere { <3.8, 0, 0>, 0.2 }
    rotate <0, 0, 15>
  }}
    object { union {
    cylinder { <2, 0, 0>, <3.8, 0, 0>, 0.15 }
    sphere { <3.8, 0, 0>, 0.2 }
    rotate <0, 0, -15>
  }}
}

#declare coxa =
union {
  sphere { <0, 0, 0>, 0.4 }
  cylinder { <0, -0.2, 0>, <0, -2.2, 0>, 0.3 }
}

#declare canela =
union {
  sphere { <0, 0, 0>, 0.4 }
  cylinder { <0, -0.2, 0>, <0, -2.2, 0>, 0.3 }
  sphere { <0, -2.4, 0>, 0.4 }
}

#declare sword =
union {
  cylinder { <0, 0, 0>, <0, 0, 3>, 0.3 }
  box { <-1, -0.3, 3>, <1, 0.3, 3.3> }
  box { <-0.3, -0.3, 3.3>, <0.3, 0.3, 8.3> }
  texture { gold }
}

#macro canela_peh(a)
 union{
   object { canela }
  object { peh rotate <90, 0, a> translate -2.4*y }
 }
#end

#macro coxa_canela_peh(b, a)
 union{
  object { coxa }
  object{ canela_peh(a) rotate b*z translate -2.4*y }
 }
#end

#macro pata(d, c, b, a)
 object{ coxa_canela_peh(b,a) rotate c*z rotate d*y rotate 90*x translate <2.5, -2.9, 0> }
#end

#macro canela_peh_s(a)
 union{
  object { canela }
  union {
   object { peh rotate <90, 0, -90> }
   object { sword  translate <0, -1, -1> scale -1*z }
   rotate <0, 90, 0>
   rotate <0, 0, a>
   translate -2.4*y
  }
 }
#end

#macro coxa_canela_peh_s(b, a)
 union{
  object { coxa }
  object{ canela_peh_s(a) rotate b*z translate -2.4*y }
 }
#end

#macro pata_s(d, c, b, a)
 object{ coxa_canela_peh_s(b,a) rotate c*z rotate d*y rotate 90*x translate <2.5, -2.9, 0> }
#end

union {
  object { body }
  object {
    pata_s (abertura_pata_frontal_direita, rotacao_coxa_pata_frontal_direita, rotacao_canela_pata_frontal_direita, rotacao_peh_pata_frontal_direita)
  }
  object {
    pata (abertura_pata_frontal_esquerda, rotacao_coxa_pata_frontal_esquerda, rotacao_canela_pata_frontal_esquerda, rotacao_peh_pata_frontal_esquerda)
    scale -1*y
  }
  object {
    pata (abertura_pata_traseira_direita, rotacao_coxa_pata_traseira_direita, rotacao_canela_pata_traseira_direita, rotacao_peh_pata_traseira_direita)
    translate -5*x
  }
  object {
    pata (abertura_pata_traseira_esquerda, rotacao_coxa_pata_traseira_esquerda, rotacao_canela_pata_traseira_esquerda, rotacao_peh_pata_traseira_esquerda)
    scale -1*y
    translate -5*x
  }
  translate  <posicao_x, 0, posicao_z>
  texture { radioactive }
}

plane { z, -2.46 pigment { color rgb <0, 0.2, 0.8> }}

// Original camera parameters:
// #local cam_ctr = <3,0,0>
// #local cam_vec = (<20,-20,20>-<3,0,0>)
// #local cam_sky = z

#include "camlight.inc"
// camlight(<3,0,0>,<10,10,10>,20.0,z,1.0)
camlight(<9,0,0>,<8,10,8>,35.0,z,1.0)