// Last edited on 2007-07-24 00:59:36 by stolfi
// Processed by remove-cam-lights

background{ color rgb < 0.50, 0.50, 0.50 > }

#declare tinta_prata =
  texture {
    pigment { color rgb < 0.55, 0.55, 0.50 > }
    finish { ambient 0.6 diffuse 0.8 phong 10 reflection 0.6 roughness 0.05 brilliance 4 }
  }

#declare tinta_ouro =
  texture {
    pigment { color rgb < 0.60, 0.50, 0.20 > }
    finish { ambient 0.6 diffuse 0.7 phong 10 reflection 0.8 roughness 0.05 brilliance 4 }
  }

#declare tinta_chao =
    texture {
 pigment { color rgb < 0.10, 0.10, 0.10 > }
 finish { ambient 0.6 diffuse 0.8 phong 10 reflection 0.3 roughness 0.05 brilliance 10 }
    }

#declare tinta_particulas =
  texture {
    pigment { color rgbf < 1, 1, 1, 0.9 > }
    finish { ambient 0.6 diffuse 0.8 phong 1 reflection 0 roughness 0.05 }
  }

#declare chao =
  box {
    < -8, -8, -1 >,
    < 8, 8, 0 >
  texture { tinta_chao }
}

#declare estatua =
 blob {
  threshold 0.6
  sphere { <0, -1, 0>, 1, 2 }
  sphere { <-1, 0.5, 0>, 1, 2 }
  sphere { <1, 0.5, 0>, 1, 2 }
  cylinder { <0, 0, 0>, <0, 0, 4>, 0.7, 1}
  sphere { <0, 0, 4>, 2, 1 }
  sphere { <0, 1, 3.5>, 1, -1 }
  sphere { <0, -1, 3.5>, 1, -1 }
  sphere { <0, 0, 5.5>, 0.8, 2 }
  cylinder { <-2, 0, 4>, <2, 0, 4>, 0.6, 1.5}
  texture { tinta_ouro }
 }

#declare pedestal =
union {
 object {
  box {
   <-2, -2, 0>,
   <2, 2, 0.5>
  }
 }
 object {
  cone {
   <0, 0, 0.5>, 1,
   <0, 0, 3>, 2
  }
 }
 object {
  box {
   <-2, -2, 3>,
   <2, 2, 3.5>
  }
 }
 texture { tinta_prata }
}

#declare roleta = seed(1);

object { chao }

object {
  pedestal
  scale 2
}

object {
  estatua
  translate 4*z
  scale 2
}

text {
  ttf "cour.ttf"
  "AOS PERDEDORES"
  1, 0
  scale 0.90
  rotate 90*x
  rotate 180*z
  texture { tinta_chao }
  translate <3.8, 3.2, 6.25>
}

#declare n_particulas = 1000;

 blob {
  threshold 0.6
  #while (n_particulas > 0)
   sphere { <rand(roleta)*20 - 10, rand(roleta)*20 - 10, rand(roleta)*20>, rand(roleta)*2, rand(roleta)*1 }
 #declare n_particulas = n_particulas - 1;
  #end
  texture { tinta_particulas }
 }

// Original camera parameters:
// #local cam_ctr = <0.00,0,8.00>
// #local cam_vec = (<10.00,20.0,15.00>-<0.00,0,8.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,0,8.00>,<10,10,10>,50.0,z,1.0)