// Last edited on DATE TIME by USER
// Processed by remove-cam-lights






  







 

 


background{ color rgb < 0.8, 0.80, 0.85 > }

plane {z, 0
  pigment {
    checker color rgbf <0.6,0.4,0.6, 0.6>,
    color rgbf <0.5,0,1, 0.6>
  }
  finish {reflection 0.6}
}

#declare Dourado = 
texture {
  pigment { color rgb < 0.8, 0.8, 0.2>}
  finish { specular 0.1 roughness 0.005 ambient 0.1 reflection 0.6
  }
}

#declare Chao = 
  texture {
  pigment { color rgb < 0.60, 0.20, 0.55 > }
  finish { ambient 0.6 diffuse 0.8 phong 0.5 roughness 0.5 brilliance 0.5}
  }

#declare Prata = 
  texture {
  pigment { color rgb < 0.20, 0.20, 0.20 > }
  finish { ambient 0.6 phong 0.5 reflection 0.7 roughness 0.1 brilliance 0.5 }
  }

#declare roleta = seed(34413);
#declare raio = 30;

  
#macro galho (p, V, L, r) 
union {
#if (r > 0)
cylinder {
    p,
    p+V*L,
    r
        texture {Chao}
    }
#local q = p+V*L;
#local distq=sqrt(q.x*q.x+(q.y-3)*(q.y-3)+q.z*q.z); 
#if(distq > raio)
sphere { p, 0.5 
  texture {Dourado}
}
#else
#local u1 = <0.5 - rand(roleta), 0.5 - rand(roleta), 0.5 - rand(roleta)>;
#local u2 = <0.5 - rand(roleta), 0.5 - rand(roleta), 0.5 - rand(roleta)>;

#local V1 = V+u1;
#local V2 = V+u2;

#local V1 = vnormalize (V1);
#local V2 = vnormalize (V2);

object{galho(q, V2, L-0.2, r-0.05)}
object{galho(q, V1, L-0.2, r-0.05)}
#end
    
#else
    
  sphere { p, 0.5 
    texture {Dourado}
  }
#end
}

#end

#declare ponto = <0,0,1>;
object {galho(<0,0,0>, ponto, 3, 0.5)}

// Original camera parameters:
// #local cam_ctr = <0.00,0.00,30.00>
// #local cam_vec = (<00.00,100.0,100.00>-<0.00,0.00,30.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,0.00,30.00>,<10,10,10>,20.0,z,1.0)