// Last edited on 2009-07-24 09:45:26 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

global_settings{ max_trace_level 10 }

#declare raio = 2.000;

#declare tinta_A =
  texture {
    pigment { color rgb < 1.00, 0.00, 0.00 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_AA =
  texture {
    pigment { color rgb < 0.50, 0.50, 0.50 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B =
  texture {
    pigment { color rgb < 0.30, 0.80, 0.30 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_C =
      texture {
      pigment{color rgb<0.3,0.3,0.3>}
 finish { brilliance 5 specular 2 roughness 0.01 diffuse 0.2 ambient 0.3 reflection {0,0.75 metallic} metallic }
  }

#declare tinta_D =
      texture {
      pigment{color rgb<0.9,0.7,0.1>}
 finish { brilliance 5 specular 2 roughness 0.01 diffuse 0.2 ambient 0.3 reflection {0,0.75 metallic} metallic }
  } 
   

#macro DedoVertical()
union{  
box {
    < -0.10, -0.10, -2.00 >,
    < 0.10, 0.10, 0.00 >
    texture { tinta_D }
  }

  sphere {
    < 0.0, 0.0, 0.00 >, 0.21
    texture { tinta_C }
  }
}
#end

#macro SuporteVertical(eixoPrincipalx, eixoyPegador, eixoBracox, eixoBracoy)

union {
  box {
    < -1.00, -1.00, +0.00 >,
    < 1.00, 1.00, 6.00 >
    texture { tinta_D }
  }

    object {
       SuporteHorizontal(eixoyPegador, eixoBracox, eixoBracoy) 
       rotate <eixoPrincipalx,0,0>
       translate <0.5,0.5,5> 
   }
}
#end

#macro BracoVertical1(eixoyPegador, eixoBracox, eixoBracoy)
union{  
box {
    < -0.10, -0.10, -3.00 >,
    < 0.10, 0.10, 0.00 >
    texture { tinta_D }
  }

  sphere {
    < 0.0, 0.0, -4.80 >, 0.321
    texture { tinta_B }
  }

    object {
       SuporteMaoHorizontalEsq(eixoyPegador)
       translate <1,0,-3> 
       
   }
    object {
       SuporteMaoHorizontalDir(eixoyPegador)
       translate <-1,0,-3> 
       
   }

}
#end

#macro SuporteMaoHorizontalEsq(eixoyPegador)

#declare eixoy = eixoyPegador;
#if (eixoyPegador < -30)
  #declare eixoy = -30;
#end

#if (eixoyPegador > 90)
  #declare eixoy = 90;
#end

union{   
box {
    < -1.00, -0.10, -0.10 >,
    < 0.00, 0.10, 0.10 >
    texture { tinta_D }
  }
    object {
       DedoVertical() 
       translate <0,0,.1> 
       rotate <0,-eixoy,0> 
   }
}
#end

#macro SuporteMaoHorizontalDir(eixoyPegador)

#declare eixoy = eixoyPegador;
#if (eixoyPegador < -30)
  #declare eixoy = -30;
#end

#if (eixoyPegador > 90)
  #declare eixoy = 90;
#end

union{  
  box {
      < 0.00, -0.10, -0.10 >,
      < 1.00, 0.10, 0.10 >
      texture { tinta_D }
    }
    object {
       DedoVertical() 
       translate <0,0,.1> 
       rotate <0,eixoy,0> 
   }
}
#end

#macro SuporteHorizontal(eixoyPegador, eixoBracox, eixoBracoy)
union {  
union{
box {
    < +0.00, -0.20, -0.20 >,
    < 4.00, 0.20, 0.20 >
    texture { tinta_D }
  }
sphere {
    < 0.5, 0.0, 0.00 >, 0.51
    texture { tinta_C }
  }

sphere {
    < 4.00, 0.0, 0.00 >, 0.2
    texture { tinta_C }
  }
  
}

    object {
       BracoVertical1(eixoyPegador, eixoBracox, eixoBracoy) 
       rotate <eixoBracox,0,0>
       rotate <0,eixoBracoy,0>
       translate <4,0,-0.1> 
   }
}
#end

#macro chaoz(filt) 
plane { 
z,0 
  texture { 
    pigment { 
      checker rgb<0.9,0.9,0.9>, rgb <0.7,0.7,0.7> rotate 17*z
    } 
    finish { diffuse 0.5 ambient 0.5 }
  } 
}
#end

union {
object { chaoz(0.0) }

object { SuporteVertical(0, 45, 0, 0) translate<-2, -12, 0>}
object { SuporteVertical(0,  10, 0, 0) translate<-2, -6, 0>}
object { SuporteVertical(0, -20, 0, 0) translate<-2, 0, 0>}
object { SuporteVertical(15, -20, 0, 0) translate<-2 , 6, 0> }
object { SuporteVertical(30, -20, 0, 0) translate<-2 , 12, 0>}
object { SuporteVertical(45, -20, 0, 0) translate<-2 , 18, 0>}
object { SuporteVertical(75, -15, 0, 0) translate<-2 , 24, 0> }
object { SuporteVertical(90, 0, 0, 0) translate<-2 , 30, 0> }
}

 

// Original camera parameters:
// #local cam_ctr = <0.00,5.00,5.00>
// #local cam_vec = (<15.00,-25.00,15.00>-<0.00,5.00,5.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,22.00,0.00>,<10,16,5>,28.0,z,1.0)