// Last edited on 2009-07-24 16:31:57 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_C = 
  texture {
    pigment { color rgb <1, 0, 0 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare bola1 =
sphere{
  < 0, 0, 0> , 
   0.5
  texture { tinta_C }
}

#declare corte =
box{
    <1,-1,-0.3>
    <-1,1,2>
    texture { tinta_C }
}

#macro folha()
union{
  box{
  < 0, 0, 0> , 
  <0.25,2,0.25>  
  texture { tinta_C }
  }
 
  difference{
    object{bola1}
    object{corte}
    translate < 0.25, 2.3, 0.5>
  }
}
#end

#macro haste1(alfa)
union{
  sphere{
  < 0, 0, 0> , 
   0.25
  texture { tinta_C }
  }

  sphere{
  < 0, 0, -1> , 
   0.25
  texture { tinta_C }
  }
  cylinder{
  < 0, 0, 0> , 
  < 0, 0 ,-1> ,
   0.25
  texture { tinta_C }
   }
  object{folha() rotate<0,0,alfa> translate<0,0,-1> }
}
#end

#macro haste2(alfa,beta)
union{
  sphere{
  < 0, 0, 0> , 
   0.25
  texture { tinta_C }
  }

  sphere{
  < 0, 2, 0> , 
   0.25
  texture { tinta_C }
  }

  cylinder{
  < 0, 0, 0> , 
  < 0, 2 ,0> ,
   0.25
  texture { tinta_C }
   }
  object{haste1(beta) rotate<alfa,0,0> translate<0,2,0> }
}
#end

#macro haste3(alfa,beta,gama)
union{

  box{
      <1,-1,0>
      <-1,1,.5>
      texture { tinta_C }
  }
  
  sphere{
  < 0, 0, 2> , 
   0.25
  texture { tinta_C }
  }
  cylinder{
  < 0, 0, 0> , 
  < 0, 0 ,2> ,
   0.25
  texture { tinta_C }
   }

  object{haste2(beta,gama) rotate<alfa,0,0> translate<0,0,2> }
}
#end

#declare nh=5;
#declare nv=4;
#declare nquadros=nh*nv;
#declare cini=0.0;
#declare cfin=1.0;
#declare ck=cini;
#declare cpasso=((cfin-cini)/(nquadros-0.9999));

#declare c0=0.0;
#declare c1=0.3;
#declare c2=0.7;
#declare c3=1.0;

#declare iv=0;
#while(iv<nv)
  #declare ih=0;
  #while(ih<nh)
  #if((ck>=c0)&(ck<c1))
      #declare rr = (ck-c0)/(c1-c0);
      #declare ss = (c1-ck)/(c1-c0);
      #declare alfa = ss*0 + rr*(-15);
      #declare beta = ss*0 + rr*(-45);
      #declare gama = 0;
  #end
  #if((ck>=c1)&(ck<c2))
      #declare rr = (ck-c1)/(c2-c1);
      #declare ss = (c2-ck)/(c2-c1);
      #declare alfa = ss*(-15) + rr*(0);
      #declare beta = ss*(-45) + rr*(15);
      #declare gama = ss*(0) + rr*(90);;
  #end
  #if((ck>=c2)&(ck<c3))
      #declare rr = (ck-c2)/(c3-c2);
      #declare ss = (c3-ck)/(c3-c2);
      #declare alfa = ss*0 + rr*(0);
      #declare beta = ss*(15) + rr*(0);
      #declare gama = ss*(90) + rr*(0);;
  #end
  object{haste3(alfa,beta,gama) translate<0,(ih+0.5)/nh*40,10 -(iv+0.5)/nv*20>}
  #declare ck=ck+cpasso;
  #declare ih=ih+1;
  #end
#declare iv=iv+1;
#end

// Original camera parameters:
// #local cam_ctr = <0.00,22.00,0.00>
// #local cam_vec = (<50.00,4.00,8.00>-<0.00,22.00,0.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,22.00,0.00>,<10,10,10>,60.0,z,1.0)