// Last edited on 2009-07-24 18:22:12 by stolfilocal
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare raio = 2.000;

#declare tinta_A = 
  texture {
    pigment { color rgb < 0.10, 0.80, 1.00 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }

#declare tinta_B = 
  texture {
    pigment { color rgb < 1.00, 0.80, 0.10 > }
    finish { diffuse 0.8 specular 0.1 roughness 0.005 ambient 0.1 }
  }
    

# macro peca1()

   
      box {
  <5, -10,-5>,
  <0, 0, 0>
  texture { tinta_A }
}

# end

# macro peca2(beta)

union{  
      box{
  <5, -5, -10>,
  <0, 0, 0>
  texture {tinta_A}
}

object{ peca1() rotate<beta, 0, 0> translate<0, 0, -10>}

}
#end

#macro peca3( alfa, beta )

       union{
  
  box{
   <5, -10, -5>,
   <0, 0, 0>
   texture { tinta_A }
  }

 object{ peca2(beta) rotate<-alfa, 0, 0> translate <0, -10, 0>}
 }

#end

# macro peca4 (teta, alfa, beta)

  union {
  

  box{
   <5,-5,-30>,
   <0, 0, 0>
   texture { tinta_A }
  }

  box{
   <10, -10, -35>,
   <-10, 10, -30>
   texture {tinta_B}
  }

  object { peca3(alfa, beta) rotate<-teta,0,0> translate<0,0,0>}
 }
#end
   

#declare c0 = 0.0;
#declare c1 = 0.2;
#declare c2 = 0.4;
#declare c3 = 0.6;
#declare c4 = 0.8;
#declare c5 = 1.0;

#declare nh = 5;
#declare nv = 6;
#declare nquadros = nh*nv;
#declare cini = 0.0;
#declare cfim = 1.0;
#declare cpasso = (cfim-cini)/(nquadros - 0.9999);
#declare ck = cini; 
#declare iv = 0;
#while(iv < nv)
   #declare ih = 0;
   #while(ih < nh)
      #if (( ck >= c0) & (ck< c1))
         #declare rr = (ck-c0)/(c1-c0);
         #declare ss = (c1-ck)/(c1-c0); 
         #declare teta = ss*0 + rr*(-30);
         #declare alfa = ss*0 + rr*30;
         #declare beta = ss*0 + rr*0;
      #end
      #if (( ck >= c1) & (ck< c2))
         #declare rr = (ck-c1)/(c2-c1);
         #declare ss = (c2-ck)/(c2-c1); 
         #declare teta = ss*(-30) + rr*(-30);
         #declare alfa = ss*30 + rr*90;
         #declare beta = ss*0 + rr*60;
      #end
      #if (( ck >= c2) & (ck< c3))
         #declare rr = (ck-c2)/(c3-c2);
         #declare ss = (c3-ck)/(c3-c2); 
         #declare teta = ss*(-30) + rr*0;
         #declare alfa = ss*90 + rr*90;
         #declare beta = ss*60 + rr*90;
      #end
      #if (( ck >= c3) & (ck< c4))
         #declare rr = (ck-c3)/(c4-c3);
         #declare ss = (c4-ck)/(c4-c3); 
         #declare teta = ss*0 + rr*0;
         #declare alfa = ss*90 + rr*90;
         #declare beta = ss*90 + rr*120;
      #end
      #if (( ck >= c4) & (ck< c5))
         #declare rr = (ck-c4)/(c5-c4);
         #declare ss = (c5-ck)/(c5-c4); 
         #declare teta = ss*0 + rr*30;
         #declare alfa = ss*90 + rr*0;
         #declare beta = ss*120 + rr*0;
      #end
      object{ peca4(teta, alfa, beta) translate <ih*50,0, iv*50 > }
        #declare ck = ck + cpasso;
        #declare ih = ih + 1;
   #end
   #declare iv = iv + 1;
#end

  

// Original camera parameters:
// #local cam_ctr = <50.00,50.00,50.00>
// #local cam_vec = (<100.00,100.00,100.00>-<50.00,50.00,50.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<50*(nh-1)/2,0,50*(nv-1)/2-20>,<10,-10,5>,490.0,z,1.0)