// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_carpete =
  texture{
    pigment{ color rgb < 0.15, 0.15, 0.35 > }
    finish{ diffuse 0.9 ambient 0.2 roughness 0.8 }
  }

#declare tx_pele =
  texture{
    pigment{ color rgb < 0.9, 0.8, 0.6 > }
    finish{ diffuse 0.8 ambient 0.1 roughness 0.5 }
  }

#declare tx_calca =
  texture{
    pigment{ color rgb < 0.45, 0.45, 0.65 > }
    finish{ diffuse 0.9 ambient 0.1 roughness 0.1 }
  }

#declare tx_metal =
  texture{
    pigment{ color rgb < 1.00, 0.10, 0.10 > }
    finish{ diffuse 0.7 ambient 0.1 specular 0.5 reflection 0.1 }
  }

#declare tx_farol =
  texture{
    pigment{ color rgb < 0.85, 0.85, 0 > filter 0.30 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.7 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

#declare raio = 2.000;

#declare cabeca =
  sphere{ < 0,0,0.25 >, 0.25
  texture{ tx_pele }
  }

#declare corpo =
  cone{ < 0,0,0 >, 0.35, < 0,0,1.5 >, 0
  texture{ tx_metal }
  }

#declare pernas =
  cylinder{ < 0,0,0 >, < 0,0,1 >, 0.15
  texture{ tx_calca }
}

#declare pessoa =
union{
  object { cabeca translate < 0,0,2.5> }
  object { corpo translate < 0,0,1 > }
  object { pernas }
}

#declare pessoa2 =
union{
  object { cabeca translate < 0,0,2.5> }
  object { corpo translate < 0,0,1 > texture { pigment {color rgb < 0.1,0.1,0.1 > } } }
  object { pernas }
}

#declare escada =
union{
#declare i = 0;
#while (i<2)
  #declare j = 0;
  #while (j<(2 - i))
    box { < -4.1,-1.5 + j*1.5 ,2*i >, < 4.1,-1.5 + (j+1)*1.5,2*(i+1) >
    texture { tx_carpete } }
    #declare j = j + 1;
  #end
  #declare i = i + 1;
#end
}

#declare chao =
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

union{
  object{ chao  texture{ tx_xadrez } }
  object{ escada }
  #declare i = 0;
  #while (i<3)
    #declare j = 0;
    #while (j< 10)
      #if (mod((j+1)*(i+1),7) = 1)
      object { pessoa2 translate < -4 + 0.73*(j+1), 2 - 2*i , 2*i >
      }
      #else
      object { pessoa translate < -4 + 0.73*(j+1), 2 - 2*i , 2*i >
      }
      #end
      #declare j = j + 1;
    #end
    #declare i = i + 1;
  #end
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 5.00, 5.00, 2.00 >;
#declare dist_camera = 10.0;
#declare intens_luz = 1.30;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)