// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_red = 
  texture{
    pigment{ color rgb < 1.00, 0.0, 0.10 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_preto = 
  texture{
    pigment{ color rgb < 0.0, 0.0, 0.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da pessoa:
#declare cabeca = 
  sphere{ <0,0,1>, 1
    texture{ tx_preto }
  };

#declare pescoso =
  cylinder{ <0,0,-0.5>, <0,0,0.0>, 0.2
    texture{ tx_preto }
  };

#declare bracoDir =
  cylinder{ <0.2,-2,-1>, <0,-1,0>, 0.4
    texture{ tx_preto }
  };

#declare bracoEsq =
  cylinder{ <0.2,2,-1>, <0,1,0>, 0.4
    texture{ tx_preto }
  };

#declare corpo =  
  box{ <0.8,-1.1,-3>, <-0.8, 1.1,-0.3> texture{tx_red} } 

#declare perna =
  cylinder{ <0,0,-3>, <0,0,-5>, 0.45
    texture{ tx_preto }
  };

#declare pessoa = 
  union{
    object{ cabeca }
    object{ pescoso }
    object{ bracoDir translate < 0, 0,-0.8 >}
    object{ bracoEsq translate < 0, 0,-0.8 >}
    object{ corpo }
    object{ perna translate < 0, -0.5,0 > }
    object{ perna translate < 0, 0.5,0 > }
    scale 0.2
    translate < 0, 0, 2 >
  }

#declare pessoa2 = 
  union{
    object{ cabeca }
    object{ pescoso }
    object{ bracoDir translate < 0, 0,-0.8 >}
    object{ bracoEsq translate < 0, 0,-0.8 >}
    object{ corpo texture{tx_xadrez} }
    object{ perna translate < 0, -0.5,0 > }
    object{ perna translate < 0, 0.5,0 > }
    scale 0.2
    translate < 0, 0, 2 >
  }

#declare boxEscada = 
  box{ <0.5,-5.5,0>, <-0.5,4.5,1> texture{tx_fosca} }  
#include "eixos.inc"

// Aqui está a cena
union{

  //eixos  
  object{ eixos(3.00) }

  //escada
  #declare i = 0;
  #declare k = 0;
  #while (k <6 )
    object {boxEscada translate <i,0,k> }  
    #declare i = i - 1;    
    #declare k = k + 1;
  #end

  //todas linhas de pessoas
  #declare i = 0;
  #declare k = 0;
  #while (k <6 )
    //fileira de pessoas
    #declare j = -5;
    #while (j <5 )
      #if(j = k | i = j)
        object {pessoa2 translate <i,j,k> }
      #else
        object {pessoa translate <i,j,k>}
      #end          
      #declare j = j + 1;
    #end

    #declare i = i - 1;    
    #declare k = k + 1;
  #end
  scale 0.6

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 15.00, 7.00, 5.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)