// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

#include "colors.inc"
#include "textures.inc"
#include "woods.inc"
#include "stones.inc" 


background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_chao = 
  texture{
    pigment{ color rgb < 0.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_origem = 
  texture{
    pigment{ color rgb < 1.0, 0.00, 0.00 > }
    finish{ diffuse 0.1 ambient 0.9 }
  }

#declare tx_marmore = PinkAlabaster

#declare tx_letra = Chrome_Metal



// ======================================================================
#declare un = 2.0;
#declare firstSeed = seed(6031769);

#macro charBloco(_tx_bloco, _tx_letra)
  object{
    union{  
      object{ box{ <-0.5,-0.5,0>, <0.5,0.5,0.5> }  texture {_tx_bloco} }
      object{ text{ ttf "arial.ttf" chr(mod((rand(firstSeed) * 1000),(125-32))+32) 0.02, 0.0 } translate <-0.4, -0.25 , 0.5> texture {_tx_letra} }
    }
  }
#end

#macro linhaBloco(tam ,_tx_bloco, _tx_letra)
  union{
    #declare i = 0;
    #while (i < tam)
      object{charBloco(_tx_bloco, _tx_letra) translate < i*1 - tam*0.5 + 0.25,0,0>}
      #declare i = i+1;
    #end
    }
#end


#macro bloco(tam_l, tam_c ,_tx_bloco, _tx_letra)
  union{
    #declare j = 0;
    #while (j < tam_l)
      object{linhaBloco(tam_c, _tx_bloco, _tx_letra) translate <0,  j*1 - tam_l*0.5 + 0.25,0>}
      #declare j = j+1;
    #end
  }
#end

// ======================================================================
// DESCRIÇÃO DA CENA 
  

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

// Aqui está a cena, finalmente:
#declare pedestalBase = 
  union{
    box{ <-3,-3,0>, <+3,+3,1> }
    cylinder{ <0,0,1>, <0,0,5>, 1 }
  }

#declare pedestalCompleto1 =
  union{
    object{ pedestalBase texture {tx_marmore} }
    object{ bloco(7, 5, tx_marmore, tx_letra) rotate <30,0,0> translate <0,0,5> }
  }

#declare pedestalCompleto2 =
  union{
    object{ pedestalBase texture {tx_marmore} }
    object{ bloco(4, 8, tx_marmore, tx_letra) rotate <90,0,0> translate <0,0,7> }
  }


union{
  object{ chao texture{tx_chao}  translate < 0,0,-0.01 >}
  sphere{ < 0,0,0>, 0.1 texture { tx_origem }}

  object{ pedestalCompleto1 rotate <0,0,180> translate <5,0,0>}

  object{ pedestalCompleto2 rotate <0,0,180> translate <-10,0,0>}

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 25.0;


#declare dir_camera = < 5.00, 15.00,    10 >;

//#declare dir_camera = < 1.00, 15.00,    3 >;
//#declare dir_camera = < 15.00, 1.00,    3 >;

//#declare dir_camera = < 1.00, 15.00,    10 >;
//#declare dir_camera = < 15.00, 1.00,    10 >;



#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)