// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

#include "textures.inc"

background{ color rgb < 0.15, 0.40, 0.95 > }

#declare tx_verde =
  texture{
    pigment{ color rgb < 0.10, 0.90, 0.10 > }
  }

#declare tx_azul =
  texture{
    pigment{ color rgb < 0.15, 0.30, 1.00 > }
  }

#declare tx_2 =
  texture{
    pigment{ color rgb < 0.85, 0.90, 0.30 > }
  }

#declare tx_3 =
  texture{
    pigment{ color rgb < 0.85, 0.60, 0.30 > }
  }

#declare chao =
  box{ <-50,-50,-10>, <+20,+20,0> }

#declare cilindro =
  cylinder { <0,0,0> <0,0,1> 0.1 texture { tx_3 } }

#macro chassis(alfa, beta, gama)
  union {
    box { <-1,-1,0>, <1,1,0.2> texture { tx_2 } }
    object { pernaA(beta, gama) translate <0,-0.5,-1> rotate alfa*y }
    object { pernaA(beta, gama) translate <0,0.5,-1> rotate alfa*y }
  }
#end

#macro pernaA(beta, gama)
  union {
    object { cilindro }
    sphere { <0,0,0> 0.1 texture {tx_3} }
    object { pernaB(gama) translate <0,0,-1> rotate beta*y }
  }
#end

#macro pernaB(gama)
  union {
    object { cilindro }
    object { pe() rotate gama*y }
  }
#end

#macro pe()
  cone { <0,0,0> 0.1 <0.3,0,0> 0 texture { tx_3 } }
#end

#macro interpola(ta, va, tb, vb, tt)
  #local s = (tt - ta) / (tb-ta);
  ((1-s)*va + s*vb)
#end

#declare alfa0 = 0; #declare alfa1 = -30; #declare alfa2 = 0; #declare alfa3 = 0; #declare alfa4 = 0;
#declare beta0 = 0; #declare beta1 = 90; #declare beta2 = 0; #declare beta3 = 0; #declare beta4 = 0;
#declare gama0 = 90; #declare gama1 = 90; #declare gama2 = 90; #declare gama3 = 180; #declare gama4 = 90;

#declare t0 = 0.000;
#declare t1 = 0.250;
#declare t2 = 0.500;
#declare t3 = 0.750;
#declare t4 = 1.000;

#include "eixos.inc"

  #if ((clock >= t0) & (clock <= t1))
    #declare alfa = interpola(t0, alfa0, t1, alfa1, clock);
    #declare beta = interpola(t0, beta0, t1, beta1, clock);
    #declare gama = interpola(t0, gama0, t1, gama1, clock);
  #end
  #if ((clock >= t1) & (clock <= t2))
    #declare alfa = interpola(t1, alfa1, t2, alfa2, clock);
    #declare beta = interpola(t1, beta1, t2, beta2, clock);
    #declare gama = interpola(t1, gama1, t2, gama2, clock);
  #end
  #if ((clock >= t2) & (clock <= t3))
    #declare alfa = interpola(t2, alfa2, t3, alfa3, clock);
    #declare beta = interpola(t2, beta2, t3, beta3, clock);
    #declare gama = interpola(t2, gama2, t3, gama3, clock);
  #end
  #if ((clock >= t3) & (clock <= t4))
    #declare alfa = interpola(t3, alfa3, t4, alfa4, clock);
    #declare beta = interpola(t3, beta3, t4, beta4, clock);
    #declare gama = interpola(t3, gama3, t4, gama4, clock);
  #end

union{
  object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_verde } }

  object { chassis(alfa, beta, gama) translate <0,0,sin(clock* (2*pi))> }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 15.00, 16.00, 2.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)