// Last edited on DATE TIME by USER
// Processed by remove-cam-lights

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2
  }

#declare arquibancada =
  texture{
    pigment{ color rgb < 0, 1, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_escada =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_pele =
  texture{
    pigment{ color rgb < 1.00, 0.721, 0.513 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_camisa_1 =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_camisa_2 =
  texture{
    pigment{ checker color rgb < 0, 0, 0 >, color rgb < 1, 1, 1 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 0.15
  }

#declare tx_cadeira =
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_grama =
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare corpo=
        cone {<0,0,0>, 0.35,
             <0, 0 ,0.8> , 0.1}

#declare cabeca =
        sphere{ < 0,0,0.85 >, 0.25}

#declare torcedor_1 =
        union {
                object{corpo texture {tx_camisa_1}}
                object{cabeca texture {tx_pele}}
}

#declare torcedor_2 =
        union {
                object{corpo texture { tx_camisa_2}}
                object{cabeca texture {tx_pele}}
}

#macro escada (n_degrau, largura)
  union{

        #declare i=0;
        #while (i<n_degrau)
                box {<-i,0,0> , <-(1+i), largura,(1+i)>}
                #declare i = i+1;
        #end
        }
#end

#declare roleta = seed(154687);

#macro cadeira (textura)
        union{

            box{<0,0,0> , <-0.7, 0.7, 0.1>}
            box{<-0.6, 0, 0.05,> , <-0.7, 0.7, 0.7> }

            #if (rand(roleta)<0.25)
                object {torcedor_1 translate <-0.35, 0.35, 0.1>}
            #else

                #if (rand(roleta)<0.5)
                        object {torcedor_2 translate <-0.35, 0.35, 0.1>}
                #end
            #end

            texture {textura}
        }

#end

#macro secao(nfilas,assentos)

        union{
                object {escada (nfilas, assentos) texture {arquibancada}}

                #declare k=0;
                #while (k<nfilas)

                        #declare l=0;
                        #while (l<assentos & ((nfilas-k)>1))

                                object {cadeira(tx_cadeira) translate <-(k),0.15+l,1+k>}

                                #declare l = l+1;
                        #end

                        #declare k = k+1;
                #end
        }
#end

#declare mid_line =

    box{<0, 14.8, -1>,
        <21, 15.2, 0.02>
        texture {
                pigment{ color rgb < 1, 1, 1.00 > }
                finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
        }
    }

#declare mid_circle =

        union{
            difference{

                    cylinder{
                            <0,0,-1>,
                            <0,0,0.02>
                            3
                            }

                    cylinder{
                            <0,0,-1>,
                            <0,0,0.02>
                            1.6
                            }

            }
        texture {
                                pigment{ color rgb < 1, 1, 1.00 > }
                                finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
        }
}

#macro setor(altura, comprimento)
        union {

        object {secao(altura,comprimento)}
        object {escada(altura,1.5) translate <0, comprimento, 0>  texture {tx_escada}}
        object {secao(altura,comprimento) translate <0, comprimento+1.5, 0>}
        object {escada(altura,1.5) translate <0, (2*comprimento)+1.5, 0> texture {tx_escada}}
        object {secao(altura,comprimento) translate <0, (2*comprimento)+3, 0>}

}
#end

#macro gramado(Tamanho, Largura)
  box{ <0,0,-1>, <Largura,Tamanho,0> }

        texture {tx_grama}
#end

#declare ALT = 8;
#declare COMP = 9;
#declare LARG = 6;
union {
        object{mid_line}
        object{mid_circle translate <10.5,15,0>}
        object{setor(ALT,COMP)}
        object{setor(ALT,LARG) rotate -90*z scale <1,-1, 1>}
        object{setor(ALT,COMP) scale <-1, 1 ,1> translate <(3*LARG)+3, 0, 0> }
        object{setor(ALT,LARG) rotate -90*z translate <0, (3*COMP)+3, 0> }
        object{gramado((3*COMP)+3,(3*LARG)+3)}
}

#include "eixos.inc"
#include "camlight.inc"
#declare centro_cena = < 6.00, 12.00, 1.00 >;
#declare raio_cena = 40.0;
#declare dir_camera = < 30, 12, 25.00 >;
#declare dist_camera = 40.0;
#declare intens_luz = 1.50;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)