// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

#include "colors.inc"

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.90, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 0.00, 0.74, 0.90 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_espelho1 = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.92, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

#declare caixa = 
  box{ <-2,-2,-1>, <2,2,0.5>
     texture {tx_plastico}	 
  }

#declare buraco = 
  box{ <-1.5,-1.5,-0.5>, <1.5, 1.5, 1>
     texture {tx_espelho}
 }

#declare suporte =
  cylinder {
    <0,0,-0.9>, <0,0,3>
    0.45
    texture{tx_plastico}
  }
  
#declare olho = 
  sphere{
  < 0,0,0 >, 0.15 
  texture {tx_vidro}
}
 
 
#declare cara =
  sphere {
    < 0,0,0>, 0.85 
    texture {tx_fosca }
  }
  
#declare chapeu =
  cone {
       <0,0,0>, 0.65
       <0,0,1>, 0
       texture {tx_xadrez}
  }

#declare boca =
  cone {
       <0,0,0>, 0.2
       <0,0,0.15>, 0.3
       texture {tx_plastico}
  }

#declare nariz =
  sphere {
     <0,0,0>, 0.17 
     pigment {color Red}
  }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(3.00) }
  object {
    union{
      difference {
        object { caixa }
        object { buraco }
      }
      object{ suporte rotate -30*x}
      object{ 
        union {
            object { cara }
            object { olho translate <0.50,0.55,0.25> }
            object { olho translate <0.70,-0.2,0.25> }
	    object { chapeu translate <0,0,0.55> }
	    object { boca translate <0.55, 0.15, -0.4>}
	    object { nariz translate <0.75, 0.18, 0> }
        }  
        translate <0,1.75, 3> 
     }
    }
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)