// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = texture {
  pigment{ color rgb < 0.10, 0.80, 1.00 > }
  finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
}

#declare tx_fosca = texture {
  pigment{ color rgb < 1.00, 0.80, 0.10 > }
  finish{ diffuse 0.9 ambient 0.1 }
}

#declare tx_espelho = texture {
  pigment{ color rgb < 1.00, 0.85, 0.30 > }
  finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
}

#declare tx_vidro = texture {
  pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
  finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
}

#declare tx_xadrez = texture {
  pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
  finish{ diffuse 0.9 ambient 0.1 }
  scale 2.0
}

// ======================================================================
// DESCRIÇÃO DA CENA 


// ----------------------------------------------------------------------
// Partes do boneco:

// Chapeu: OK
#declare chapeu = cone {
  <0.0, 0.0, 0.0>, 0.0
  <0.0, 0.0, -1.0>, 1.0
  texture { tx_plastico }
}

// Cabeca:
#declare cabeca = sphere {
   <0.0, 0.0, 0.375>, 0.75
  texture { tx_plastico }
}

// Bracos:
#declare bracos = cylinder {
  <-1.5, 0.0, 0>, <1.5, 0.0, 0>, 0.25
  texture { tx_plastico }
}

// Corpo:
#declare corpo = cone {
  <0.0, 0.0, 0.0>, 0.5
  <0.0, 0.0, -1.5>, 1.5
  texture { tx_plastico }
}

// Perna:
#declare perna = cylinder {
  <0.0, 0.0, 0.0>, <0.0, 0.0, -1.5>, 0.25
  texture { tx_plastico }
}

#declare boneco = object {
  union {
    object { chapeu translate <0.0, 0.0, 4.0> }
    object { cabeca translate <0.0, 0.0, 2.5> }
    object { bracos translate <0.0, 0.0, 2.1> }
    object { corpo  translate <0.0, 0.0, 2.0> }
    object { perna  translate <0.5, 0.0, 0.5> }
    object { perna  translate <-0.5, 0.0, 0.5> }
  }
}

// ----------------------------------------------------------------------
// Partes da caixa:

#declare tampa = object {
  difference {
    box { <0.0, 0.0, 1.0>, <4.0, 4.0, 0.0> texture { tx_fosca } }
    box { <0.25, 0.25, 0.5>, <3.75, 3.75, -0.5> texture { tx_fosca } }
  }
}

#declare caixa = object {
  difference {
    box { <0.0, 0.0, 0.0>, <4.0, 4.0, 4.0> texture { tx_fosca } }
    box { <0.25, 0.25, 0.5>, <3.75, 3.75, 4.5> texture { tx_fosca } }
  }
}

#declare chao = box{ <-20,-20,0>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object { eixos(3.00) }
  object { boneco scale <0.75, 0.75, 0.75> rotate <-45, 20, 90> translate <-1, -1, 0.5>}
  object { tampa rotate <65, 0, 0> translate <-3, -3, 0> }
  object { caixa translate <-3, -3, -4>}
  object { chao  translate < 0,0,-5 > texture{ tx_xadrez } }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)