// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_vermelho = 
  texture{
    pigment{ color rgb < 1.00, 0.20, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 1/2.0
  }

#declare tx_xadrez_vermelho =
  texture{
    pigment{ checker color rgb < 0.60, 0.22, 0.10 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 1
  }

#declare txt_fun = 
  pigment {
    bozo
    turbulence 0.5
    frequency 3
    color_map {
      [0.00 color rgb <1, 0.25, 0.25>]
      [0.33 color rgb <1, 1, 0.25>]
      [0.50 color rgb <0.25, 1, 0.25>]
      [0.66 color rgb <0.25, 0.25, 1>]
      [1.00 color rgb <1, 0.25, 0.25>]
  }
}


// ======================================================================
// DESCRIÇÃO DA CENA 

//MOLA SAINDO DA CAIXA


#declare MOLA_DIRECTION_SQUARED = <   -7, 0.00, 0.00>;
#declare MOLA_DIRECTION_LINEAR  = <   4, 0.00, 5.00>;
#declare MOLA_NSEGS = 9;
#declare MOLA_R1 = 0.5;
#declare MOLA_R2 = 1.0;

#macro P(i)
  MOLA_DIRECTION_SQUARED*((i*i)/(MOLA_NSEGS*MOLA_NSEGS)) + MOLA_DIRECTION_LINEAR*i/MOLA_NSEGS
#end
  
union{
  //"MOLA"
  #declare Index = 0;
  #while(Index < MOLA_NSEGS)
    #declare Pa = P(Index-0.1);
    #declare Pc = P(Index+1.1);
    //Se não forem paralelo, um deles acaba dentro do outro e fica feito. Por isso, pego o ponto médio ao invés de P(Index+0.5)
    #declare Pb = (Pa+Pc)/2;  
    cone { Pa,  MOLA_R1, Pb,  MOLA_R2 texture{ tx_plastico } } 
    cone { Pb,  MOLA_R2, Pc,  MOLA_R1 texture{ tx_plastico } }
    #declare Index = Index + 1;
  #end
}
//CABEÇA DA MOLA
sphere {
  P( MOLA_NSEGS) , 1.5
  pigment { txt_fun }
}

//NARIZ DA MOLA
cone { P(MOLA_NSEGS)  ,  1
	P(MOLA_NSEGS+3), 0
	texture{ tx_vermelho } 
} 

//CAIXA DE SURPRESAS

#macro caixa(P1, P2, raio, espessura, textura) //P2=lado aberto
  #declare hole_offset = vnormalize(P2-P1)*espessura;
   difference{ 
     object { cylinder { P1            , P2            , raio           texture{ textura } } }
     object { cylinder { P1+hole_offset, P2+hole_offset, raio-espessura texture{ textura } } }
   }
#end

//CAIXA
caixa(<0, 0, 0>, <0, 0, 2>, 2, 0.15, texture{ tx_xadrez } )

//TAMPA
caixa(P(MOLA_NSEGS+3), P(MOLA_NSEGS+2.5), 2.1, 0.1, texture{ tx_xadrez_vermelho } )

#macro P(i)
  <0.01*i*i*i, 0, 0.7*i>
#end

   


#include "camlight.inc"
#declare centro_cena = <0,0,4>;
#declare raio_cena = 8.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)