// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_vermelho = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

#declare caixa_ext =
	cylinder{
		< 0.00, 0.00, 0.00 >,
		< 0.00, 0.00, 2.00 >,
		3.00
		texture{ tx_fosca }
	}

#declare caixa_int =
	cylinder{
		< 0.00, 0.00, 0.02 >,
		< 0.00, 0.00, 3.00 >,
		2.80
		texture{ tx_vermelho }
	}

#declare tampa_ext =
	cylinder{
		< 0.00, 0.00, 0.00 >,
		< 0.00, 0.00, 1.00 >,
		3.00
		texture{ tx_fosca }
	}

#declare tampa_int =
	cylinder{
		< 0.00, 0.00, -1.00 >,
		< 0.00, 0.00, +0.08 >,
		2.80
		texture{ tx_vermelho }
	}

#declare bolinha = 
  sphere{ < 0,0,0 >, 0.80
	texture{ tx_plastico }
}
 
#declare myCone =
  cone{
    < 0.00, 0.00, 0.00 >, 0,
		< 0.00, 0.00, 1.80 >, 1
    texture{ tx_espelho }
  }
  
#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(4.00) }

  object{ chao  translate < 0,0,-1 > texture{ tx_xadrez } }

	object{ bolinha translate < 0,0,3.0 >}
	
	object{ myCone translate < 0,0,0.5 >}

	difference {
		object{ tampa_ext rotate 45 *x translate < 0,0,4 > }
		object{ tampa_int rotate 45 *x translate < 0,0,4 > }
	}

  difference { 
    object { caixa_ext }
		object { caixa_int }
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 3.00 >;
#declare raio_cena = 8.0;
#declare dir_camera = < 5.00, 10.00, 6.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)