// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 0.70, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_preto =
  texture{
    pigment{ color rgb < 0, 0, 0 > }
    finish{ diffuse 0.9 ambient 0.1 reflection 0.7*< 1.00, 0.85, 0.30 >}
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_caixa =
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 >}
    finish{ diffuse 0.8 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:
  
#declare cabeca =
  sphere{
    < 0,0,0 >,1.2 
    texture{ tx_plastico }
  }

#declare olho =
  sphere{
    < 0,0,0 >,0.2
    texture{ tx_preto }
  }
 

#declare nariz =
  cylinder{
    < 0,0,0 >,
    < 0,0,1 >,
    0.18
    texture{ tx_fosca }
  }

#declare buraco_boca=
   box{
   <-0.3,-0.3,0>,
   <0.3,0.3,0.2>
   }
 
#declare pescoso = 
  cylinder{
    < 0,0,0 >,
    < 0,0,7 >,
    0.9
    texture{ tx_fosca }
  }

#declare caixa =
	difference{
		box{
		<-2,-2,0>,
		<2,2,4>
		}
		box{
                <-1.8,-1.8,0.5>,
                <1.8,1.8,4.3>
                }
	texture{ tx_caixa }
	}

#declare rosto=
	union{
  		object{ olho translate <1,-0.5,0.6> }
		object{ olho translate <1,0.5,0.6>}
		object{ nariz rotate 90*y translate <1.2,0,0>}
		difference
		{
			object{cabeca}	
			object{ buraco_boca translate <1.2,0,-0.6>}
		}
	}


#declare caixa_surpresa=
	union{
	  object{ caixa }

	  object{ pescoso translate <0,0,0> }

	  object{ rosto translate <0,0,7.3> }
	
	}
		
  

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }	

  object{ caixa_surpresa rotate 30*z}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 15.0;
#declare dir_camera = < 20, 0, 15.00 >;
#declare dist_camera = 15.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)