// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
 
#declare bola =
  sphere{
    < -6.00, -3.00, 1.20 >, 0.5
    texture{ tx_espelho }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare caixa1 =
  box { 
    <-8, -1, -6>, < -4, -5, -2> 
    texture{ tx_fosca }
  }

#declare caixa2 =
  box { 
    <-7.75, -1.25, -5.75>, < -4.25, -4.75, 0> 
    texture{ tx_fosca }
  }

#declare pino = 
  cylinder{
    < -6.00, -3.00, -5.75 >,
    < -6.00, -3.00, 1.00 >,
    0.30
    texture{ tx_plastico }
  }

#declare chapeu =
  cone {
    < -6.00, -3.00, 1.20>, 0.45,
    < -6.00, -3.00, 2.20>, 0
    texture {tx_plastico}
  }

#declare tampa = 
  box { 
    <-8.3, -1, 0.8>, < -8.1, -5, 4.7>
    rotate y*-20
    texture{ tx_fosca }
  }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  //object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

  difference {
    object{ caixa1 }
    object{ caixa2 }
  }
  object {pino}
  object {bola}
  object {chapeu}
  object {tampa}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)