// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = texture {
  pigment{ color rgb < 0.10, 0.80, 1.00 > }
  finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
}

#declare tx_fosca = texture {
  pigment{ color rgb < 1.00, 0.80, 0.10 > }
  finish{ diffuse 0.9 ambient 0.1 }
}

#declare tx_espelho = texture {
  pigment{ color rgb < 1.00, 0.85, 0.30 > }
  finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
}

#declare tx_vidro = texture {
  pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
  finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
}

#declare tx_xadrez = texture {
  pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
  finish{ diffuse 0.9 ambient 0.1 }
  scale 2.0
}

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare pinca = difference {
  box { <0, 0, 0>, <3, 1, 1> }
  box { <0, 0, 0>, <1.5, 1.5, 1.5>
    rotate <0, 45, 0>
    translate <2.2, -0.25, 1.2>
  }
  box { <0, 0, 0>, <2, 1.5, 0.3>
    translate <-0.1, -0.25, -0.1>
  }
}

// abertura: 0 para fechar e 1 para abrir.
#macro garra (abertura)
  object {
    union {
      box { <-1, 0, -2.5>, <0, 1, 2.5> }
      object { pinca
        texture { tx_fosca }
        translate <0, 0, abertura*1.5>
      }
      object { pinca
        texture { tx_fosca }
        scale <1, 1, -1>
        translate <0, 0, -abertura*1.5>
      }
      cylinder {
        <-1, 0.5, 0>, <-5, 0.5, 0>, 0.5
      }
    }
  }
#end

#declare chao = box { <-20, -20, 0>, <20, 20, 0> }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union {
  object { eixos(3.00) }
  object { chao texture { tx_xadrez } translate <0, 0, -1.5> }
  object { garra(1)
    texture { tx_plastico }
    scale 0.5
    rotate <0, 90, -45>
    translate <2, -2, 2>
  }
  torus {
    1, 0.45
    texture { tx_plastico }
    rotate <0, 0, 45>
    translate <2, -2, 0.5>
  }
  object { garra(0.5)
    texture { tx_plastico }
    scale 0.5
    rotate <0, 90, -45>
    translate <1, 1, 2>
  }
  torus {
    1, 0.45
    texture { tx_plastico }
    rotate <0, 0, 45>
    translate <1, 1, 0.5>
  }
  object { garra(0)
    texture { tx_plastico }
    scale 0.5
    rotate <0, 90, -45>
    translate <0, 3.5, 2>
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)