// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.2 roughness 0.005 }
  }

#declare tx_vermelho = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.2*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare apoio =
	box{
		< +1.50, 0.00, 0.00>,
		< -1.50, -0.20, 2.00>
		texture{ tx_plastico }
	}
#declare pah =
	box{
		< 1.50, 1.50, 0.20>,
		< -1.50, 0.00, 0.00>
		texture{ tx_plastico }
	}

#declare furo =
	box{ 
		< 1.00, -1.00, 0.00 >,
		< -1.00, 1.00, 2.00 >
		texture{ tx_plastico }
	}

#declare cabo =
	cylinder{
		< 0.00, 0.00, 0.50 >,
		< 0.00, -5.00, 0.50 >,
		0.50
		texture{ tx_vermelho }
	}

#declare eixo_giro =
	cylinder{
		< 1.20, 0.00, 0.00>,
		< -1.20, 0.00, 0.00>,
		0.05
	}

#declare biscoito =
	torus{ 1, 0.45  texture{ tx_fosca }}

#declare pega =
	box{
		< 0.50, 2.50, 0.20>,
		< -0.50, 0.00, 0.00>
		texture{ tx_plastico }
	}

#declare mordida = 
  sphere{ < 0,0,0 >, 1
	texture{ tx_fosca }
}

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro segurador (rot)
		union{
		object{ pega rotate rot *x translate < 0, -0.20, 1.8 >}
		object{ eixo_giro translate < 0, -0.1, 1.8>}
		object{ pah }
		#if ( rot < -25 )
			difference {
				object{ biscoito rotate 90 *x translate < 0, 1.5, 0.5 > }
				object{ mordida translate < 0, 3, 0.5 > }
			}
		#else
			object{ biscoito rotate 90 *x translate < 0, 1.5, 0.5 > }

		#end


		object{ cabo translate < 0,-0.20, 0>}
		difference{
			object{ apoio }
			object{ furo translate < 0,0,1.50 >}
		}

		rotate 45 *x
		translate < 0,2,3>
	}
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ chao  translate < 0,0,-1 > texture{ tx_vidro } }

	object{ segurador(0) }
	object{ segurador(-15) translate < 0, 5, 0>}
	object{ segurador(-30) translate < 5, 0, 0> }

}

#include "camlight.inc"
#declare centro_cena = < 2.00, 3.00, 3.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 7.00, 2.00, 6.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)