// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// =========================================		=============================
// CORES E TEXTURAS

background{ color rgb < 1.0, 1.0, 1.0 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 15.8 roughness 0.1 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 0.02, 0.02, 0.02 > }
    finish{ diffuse 0.9 ambient 0.1 specular 5.0 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 1.00 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.1 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.42, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 1.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 


// Partes da cena:

#declare box0 = 
  box{ < -1, 1, -1 >, 
			 <  1, 1.1, 1>
			 texture{ tx_plastico } 
	}  

#declare box1 = 
  box{ < -1, 1.1, 0.9 >, 
			 <  1, 2.6, 1.0 >
	}  
 
#declare box2 = 
  box{ < -1, 1.1, -0.9 >, 
			 < 1 , 2.6, -1.0 > 
	}

#declare box3 = 
  box{ < -1, 2.6, 0.92 >, 			//centro= (0,3.25, 0.95 )
			 <  1, 3.9, 0.98>
			 texture{ tx_plastico } 
	}  

#declare box4 = 
  box{ < -1, 2.6, -0.92 >, 
			 <  1, 3.9, -0.98 >
			 texture{ tx_plastico } 
	}  

  
#declare cilindro = 
  cylinder{
    < 0, +1.00, 0 >,
    < 0, -3.00, 0 >,
    0.2
    texture{ tx_fosca }
  }


  
#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#macro pegador (angulo)
union {
	object{ cilindro }
	object{ box1}
	object{ box2}
	object{ box0}	
	object{ box3 
					translate -< 0, 2.6, 0.95 >
					rotate <-angulo,0,0>
					translate <0, 2.6,0.95> 
					
	}
	

	object{ box4 
					translate -< 0, 2.6, -0.95 >
					rotate < angulo,0,0>
					translate <0, 2.6,-0.95> 
								 
	}
}
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  //object{ eixos(3.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
	
	object{ pegador(2)  translate <-4, -5, 2> }
	object{ pegador(25) translate <-3, -5.5, -1>}
	object{ pegador(45) translate < -1, 0.5 , 1.2>}
}


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)