// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.4, 0.6, 0.8 > }

#declare tx_metal = 
  texture{
    pigment{ color rgb < 0.70, 0.70, 0.70 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.05 }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#include "textures.inc"

#declare s_ext =
  sphere{
    < 0.00, 0.00, 0.00 >, 3
  }

#declare s_int =
  sphere{
    < 0.00, 0.00, 0.00 >, 2.9
  }

#declare cut1 =
  box{ <3,3,3>, <-3, -3, -2.3>
  }

#declare b_ext =
  cylinder{ <0, 0, 4>, <0, 0, -4>, 0.7
  }

#declare b_int = 
  cylinder{ <0, 0, 4.01>, <0, 0, -4.01>, 0.6
  }

#declare cut2 =
  box{ <2,-1,-4.1>, <-2, 0.4, 4.1>
  }

#declare pino = 
  cylinder{ <0.7, 0, 0>, <-0.7, 0, 0>, 0.22
  texture{ Chrome_Metal }
  }

#declare ponta = difference{
    difference{
      object{ s_ext texture{ Chrome_Metal }}
      object{ s_int texture{ Chrome_Metal }}
    }
    object{ cut1 texture{ Chrome_Metal }}
  }

#declare braco = difference{
    difference{
      object{ b_ext texture{ Chrome_Metal }}
      object{ b_int texture{ Chrome_Metal }}
    }
    object{ cut2 texture{ Chrome_Metal }}
  }

#declare banda = union{
    object{ ponta scale <1.2, 1.75, 1> translate <0,11.05,2.3> }
    object{ braco translate <0,-0.4,0> rotate <-90, 0, 0> translate <0,4.1,0> }
}

#macro pegador(A, B, C, D)
  union{
    object{ banda rotate <-D, 0, 0> translate <A,B,C>}
    object{ banda rotate <0, 180, 0> rotate <D, 0, 0> translate <A,B,C>}
    object{ pino translate <A,B,C>} 
  }
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ pegador(3, 0, 0, 8) }
  object{ pegador(-8, 0, 0, 0) }
  object{ pegador(8, 0, 0, 16) }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 5.00, 0.00 >;
#declare raio_cena = 25.0;
#declare dir_camera = < 15.00, 25.00, 7.00 >;
#declare dist_camera = 20.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)