// CORES E TEXTURAS

#include "colors.inc"

background{ color White }

// DESCRIÇÃO DA CENA 

#declare fenda =
  box{
    <4.00, -0.05, 0.60>, <1.00, 0.30, 1.20>
    pigment{ color Gray }
  }

#declare aba =
  union{
    box{
      <4.00, 0.00, 2.0>, <0.00, 0.25, 3.0>
      pigment{ color Gray }
      rotate <0,0,0>
    }  

    box{
      <3.00, 0.00, 2.0>, <0.00, 0.25, 3.0>
      pigment{ color Gray }
      rotate <0,0,-90>
    }
  }

#declare arm =
  union{
    difference{
      box{
        <5.00, 0.00, 0.00>, <0.00, 0.25, 5.00>
        pigment{ color Gray }
      }
      object{ fenda }
      object{ fenda translate <0,0,1.5> }
      object{ fenda translate <0,0,3.0> }
    }

    difference{
      box{
       <5.00, 0.00, 0.00>, <0.00, 0.25, 5.00>
       pigment{ color Gray }
       rotate <0,0,35> translate <5,0,0>
      }
      object{ fenda rotate <0,0,35> translate <5,0,0> }
      object{ fenda rotate <0,0,35> translate <5,0,1.5> }
      object{ fenda rotate <0,0,35> translate <5,0,3> }
    } 
     
    object{ aba rotate <0,0,-40> translate <-18,2.6,0>}
    
    box{
      <0.00, 0.00, 2.0>, <-20.00, 0.25, 3.0>
      pigment{ color Gray }
    }
  } 

#macro pegador (ang)
  union{
    object{ arm translate <15,0,0> rotate <0,0,-ang>}
    object{ arm rotate <180,0,0> translate <15,0,5> rotate<0,0,ang>}
  }
#end

// CENA:

union{
  object{ pegador (10) translate <5,14,0>}
  object{ pegador (30) translate <10,-2,6>}
  object{ pegador (45) translate <0,8,14>}
}

// LUZ e CAMERA

#include "camlight.inc"
#declare centro_cena = < 20.00, 10.00, 12.00 >;
#declare raio_cena = 25.0;
#declare dir_camera = <30.00, 30.10, 50.00 >;
#declare dist_camera = 30.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)