// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare barra =
  box{ <-1,-1.5,0>, <1,1.5,0.10> }

#declare espaco1 = 
  box{ <-0.60,1.35,-0.1>, <-0.2, 2, 0.2>}

#declare espaco2 = 
  box{ <0.2,1.35,-0.1>, <0.6, 2, 0.2>}

#declare garra1 =
  box{ <-1.0,1.5,0>, <-0.6, 1.65, 0.10>}  //centro <-0.8, 2.575, 0.05>

#declare garra2 =
  box{ <-0.2,1.5,0>, <0.2, 1.65, 0.10>}  //centro <0, 2.575,0.05>

#declare garra3 =
  box{ <0.6,1.5,0>, <1, 1.65, 0.10>} //centro <0.8, 2.575, 0.05>

#declare pino = 
  cylinder{
    < 0.00, -1.50, -1.00 >,
    < 0.00, -1.50, +1.00 >,
    0.15
    texture{ tx_plastico }
  }

#macro braco()
  union {
    difference {
      object{barra texture {tx_fosca}}
      object{espaco1 texture {tx_fosca}}
      object{espaco2 texture {tx_fosca}}
    }
    object{garra1 translate -<-0.8, 1.575, 0.05> rotate x*-45 translate <-0.8, 1.575, 0.05> translate <0,-0.05,-0.03> texture {tx_fosca}}
    object{garra2 translate -<0, 1.575,0.05> rotate x*-45 translate <0, 1.575,0.05> translate <0,-0.05,-0.03> texture {tx_fosca}}
    object{garra3 translate -<0.8, 1.575, 0.05> rotate x*-45 translate <0.8, 1.575, 0.05> translate <0,-0.05,-0.03> texture {tx_fosca}} 
  }
#end

#macro segurador(A,B) // A rotaciona o braço 1 e B rotaciona o braço 2
  union {
    object{braco() translate <0,1.5,0> rotate x*A}
    object{braco() rotate y*180 translate <0,1.5,0> rotate x*B}
    object{pino rotate y*90 translate <0,1.5,0>} 
  }
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  //object{ eixos(3.00) }
  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }
  object{ segurador(93,87) translate <0,-3,0>}
  object{ segurador(105,75) translate <0,-1,0>}
  object{ segurador(125,55) translate <0,2.5,0>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)