// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb <0.80, 0.80, 0.80> }

// ======================================================================
// DESCRIÇÃO DA CENA 
// Partes da cena:
#include "eixos.inc"
#include "colors.inc"

#declare tamanho = 3;
#declare rotX = 45;

#declare dinheiro =
    box {
        <-0.2, 0, 0>, <0.2, 0.01, 1.3>
        pigment { color rgb <0, 1, 0> }
    }

#macro chao(altura)
    plane {
        z, altura 
        pigment { checker color rgb <0.4, 0.4, 0.4> color rgb <0.6, 0.6, 0.6> scale 6}
        finish { reflection 0.2 ambient 0.3 diffuse 0.1 }
    }
#end


#macro galho(n)
    cylinder {
        <0, 0, 0>
        <0, 0, n * tamanho>, n * 0.18
        pigment { color rgb <0.63, 0.31, 0.18> }
    }
#end

#macro arvore(n)
    #if (n <= 1)
        union {
            object { galho(n) }
            object {
                dinheiro
                translate <0, 0, n * tamanho>
            }
        }
    #else
        union {
            object { galho(n) }
            object {
                arvore(n - 1)
                rotate <rotX, 0, 0>
                translate <0, 0, n * tamanho>
            }
            object {
                arvore(n - 1)
                rotate <rotX, 0, 120>
                translate <0, 0, n * tamanho>
            }
            object {
                arvore(n - 1)
                rotate <rotX, 0, 240>
                translate <0, 0, n * tamanho>
            }
        }
    #end
#end

#macro copa(maior, menor)
    cone {
        <0, 0, 0>, maior 
        <0, 0, 10>, menor
        pigment { color rgb <0, 0.5, 0> }
    }
#end

#declare folhagem =
    union {
        copa(20, 12)
        object {
            copa(14, 8)
            translate <0, 0, 10>
        }
        object {
            copa(10, 3)
            translate <0, 0, 17>
        }
        object {
            copa(7, 0)
            translate <0, 0, 22>
        }
    }



// Aqui está a cena, finalmente:
union {
    object { chao(0) }
    object { arvore(5) }
    object {
        folhagem
        translate <0, 0, 13>
    }
    object {
        arvore(5)
        translate <30, 30, 0>
    }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 100.0;
#declare dir_camera = < 1.00, 20, 3 >;
#declare dist_camera = 60.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)