// ======================================================================
// CORES E TEXTURAS

background { color rgb < 0.75, 0.80, 0.85 > }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 0.4; // Raio do tronco
#declare queda = 0.8; // Fator de escala
#declare altura = 1.8; // Altura do tronco
#declare abertura = 40; // Abertura dos galhos

#declare rotz = seed(1234);

#declare folha = box {
  <-0.5, -0.1, 0>, <0.5, 0.1, 2>
  pigment {
    image_map { jpeg "100.jpg" }
    rotate <0, 0, 90>
    rotate <90, 0, 0>
    scale <1, 1, 2>
    translate <-0.5, 0, 0>
  }
}

#declare tronco = cone {
  <0, 0, 0>, raio
  <0, 0, altura>, raio * queda
  pigment {
    image_map { jpeg "tronco.jpg" }
    rotate <0, 90, 0>
    scale <1, raio, altura>
    translate <0, -raio/2, 0>
  }
}

#macro arvore(n)
  union {
    object { tronco }
    #if (n = 0)
      object { folha translate <0, 0, altura> }
    #else
      object { arvore(n-1)
        scale queda
        rotate <0, -abertura, rand(rotz) * 360>
        translate <0, 0, altura>
      }
      object { arvore(n-1)
        scale queda
        rotate <0, 0, rand(rotz) * 360>
        translate <0, 0, altura>
      }
      object { arvore(n-1)
        scale queda
        rotate <0, +abertura, rand(rotz) * 360>
        translate <0, 0, altura>
      }
    #end
  }
#end

#declare chao = box {
  <-20, -20, 0>, <20, 20, 0>
  pigment {
    image_map { jpeg "grama.jpg" }
    scale <5, 5, 1>
  }
}

union {
  object { chao translate <0, 0, -1.5> }
  object { arvore(4) rotate <0, 0, -45> translate <0, 0, -1.5> }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 2.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)