// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.2 roughness 0.005 }
  }

#declare tx_verde = 
  texture{
    pigment{ color rgb < 0.48, 0.99, 0.00 > }
  };

#declare tx_marrom = 
  texture{
    pigment{ color rgb < 0.92, 0.64, 0.51 > }
  };

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.2*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare tronco =
	cylinder{
		< 0.00, 0.00, 0.00 >,
		< 0.00, 0.00, 4.00 >,
		1.00
		texture{ tx_marrom }
	}

#declare copa =
	cone{
		< 0.00, 0.00, 0.00 >, 1.00
		< 0.00, 0.00, 1.50 >, 0.00
		texture{ tx_marrom }
	}

#declare moeda =
	cylinder{
		< 0, 0, 0.00>,
		< 0, 0, 0.5>,
		2
		texture{ tx_espelho }
	}

#declare chao = 
  box{
		<-100,-100,-1>,
		<+100,+100,0>
		texture{ tx_verde }
	}

#macro arvore (n, xScale, yScale, zScale, rot)
		union{

		#if ( n = 0 )
			union {
				object{ tronco }
				object{ copa translate < 0, 0, 4>}
				object{ moeda rotate 90 *x translate < 0, 0, 8>}
			}
		#else
			union {
				object{ tronco }
				object{ copa translate < 0, 0, 4>}
				#if ( mod(n, 2) = 0)
					object{ arvore(n-1, xScale, yScale, zScale, rot) scale <xScale, yScale, zScale> rotate rot *x translate < 0, 0, 4>}
					object{ arvore(n-1, xScale, yScale, zScale, rot) scale <xScale, yScale, zScale> rotate -rot *x translate < 0, 0, 4>}
				#else
					object{ arvore(n-1, xScale, yScale, zScale, rot) scale <xScale, yScale, zScale> rotate rot *y translate < 0, 0, 4>}
					object{ arvore(n-1, xScale, yScale, zScale, rot) scale <xScale, yScale, zScale> rotate -rot *y translate < 0, 0, 4>}
				#end
			}
		#end
	}
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ chao }

	object{ arvore(10, 0.6, 0.6, 0.8, 45) }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 5.00 >;
#declare raio_cena = 15.0;
#declare dir_camera = < 7.00, 5.00, 3.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)