// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_chocolate = 
  texture{
    pigment{ color rgb < 0.89, 0.69, 0.19 > }
    finish{ diffuse 0.8 roughness 0.5 }
  }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

#declare dinheiro =
  box{ <0,-0.1,3>, <1,0.1,3.5> texture{ tx_espelho } }

#declare galho =
  cone{ <0,0,0>, 0.5, <0,0,2>, 0 texture{ tx_chocolate } }

#declare ramos =
  cylinder{ <0,0,0>, <3,0,4> 0.5 texture{ tx_chocolate } }

#declare tronco =
  cylinder{ <0,0,0>, <0,0,6> 1 texture{ tx_chocolate } }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

// ======================================================================
// MACROS
//arvore( n, translate <A,B,C> rotate <D,E,F> aditional rotate G )
#macro arvore(n,A,B,C,D,E,F,G)

  #if(n=0)
    union{
      object{ galho rotate <D,E,F> translate <A,B,C> rotate <0,0,G> }
      object{ dinheiro translate -<0,-0.1,1> rotate <D,E,F> translate <A,B,C> rotate <0,0,G> }
    }
  #else
    union{
      object{ galho rotate <D,E,F> translate <A,B,C> rotate <0,0,G> }
      object{ dinheiro translate -<0,-0.1,1> rotate <D,E,F> translate <A,B,C> rotate <0,0,G> }
      object{ arvore(n-1,A,B,C,D,E+90,F,G) }
      object{ arvore(n-1,A,B,C,D+90,E+90,F,G+120) }
      object{ arvore(n-1,A,B,C,D-90,E+90,F,G+240) }
    }
  #end
#end

//base( arvore n, translate <A,B,C> rotate <D,E,F> )
#macro base(n,D,E,F)

    union{
      object{ tronco }
      object{ ramos translate <0,0,6> }
      object{ arvore(n,3,0,10,D,E,F,0) }
      object{ ramos rotate <0,0,120> translate <0,0,6> }
      object{ arvore(n,3,0,10,D,E,F,120) }
      object{ ramos rotate <0,0,240> translate <0,0,6> }
      object{ arvore(n,3,0,10,D,E,F,240) }
    }

#end

// ======================================================================

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ base(2,0,0,0) }
  object{ chao texture{ tx_xadrez } } 
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 3.00, 6.00 >;
#declare raio_cena = 12.0;
#declare dir_camera = < 14.00, 7.00, 7.00 >;
#declare dist_camera = 95.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)