// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:
 
#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// MACROS:

#macro arvore (nivel,tam,raio)

#declare dinheiro =
  box{
    < 0.00, 0.00, 0.00 >, <1.0*tam, 0.5*tam, 0.00> 
    texture{ tx_plastico }
  }

#local galho = 
  cylinder{
      < 0.00, 0.00, 0.00 >,
      < 0.00, 0.00, tam >,
      raio
      texture{ tx_fosca }
  }

 #if(nivel=1)
   union{
     object{ galho }
     object{ dinheiro translate<0,0,1*tam> }
   }
 #else
   union{
     object{ galho }
     object{ arvore(nivel-1,tam/2,raio/2) rotate<0,40,0> translate<0,0,0.75*tam>}
     object{ arvore(nivel-1,tam/2,raio/2) rotate<0,-40,0> translate<0,0,0.75*tam>}
   }
 #end
#end

// Aqui está a cena, finalmente:

object{ eixos(3.00) }

arvore (4,4,0.4)

object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 10.0;
#declare dir_camera = < 3.00, 4.00, 4.00 >;
#declare dist_camera = 7.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)