// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }
#include "textures.inc"
#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 1;

// Partes da cena:
#macro galho(n)
	#if (n=0)
		object {box {<0,0,0>, <1,0,2>} texture {Jade}}
	#else
		union {
			object { cylinder {<0,0,0>, <0,0,4>, 0.11 } texture {Cherry_Wood} }
			object {box {<0,0,0>, <1,0,2>} rotate <0,45,90> translate <0,0,4> texture {Jade}}
			#if (n=1)
				object { galho(n-1) rotate <0,45,90> translate <0,0,4>}
			#else
				object { galho (n-1) rotate <0,20,0> translate <0, 0, 1> }
				object { galho (n-1) rotate <0,-20,0> translate <0, 0, 3> }
			#end
		}
	#end
#end

#declare vaso =
  cone { <0,0,0>, 2, <0,0,3>, 3 }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#declare tronco =
  cylinder { <0,0,0>, <0,0,3> 0.30 } 

#declare terra=
  cylinder { <0,0,0>, <0,0,1> 2.7 }

#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(3.00) }
  object{ chao  translate < 0,0, 0 > texture{ tx_xadrez } }
  union {
	  object{ galho(3) rotate <0,30,-30> translate <0,0,6>}
	  object{ galho(3) rotate <0,-30,30> translate <0,0,6>}
	  object{ galho(3) translate <0,0,6>}
	  object{ tronco  texture {Cherry_Wood} translate <0,0,3>}
	  object{ vaso texture {PinkAlabaster} }
	  object{ terra translate <0,0,2>}
  }
}



	
#include "camlight.inc"

#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 25.0;
#declare dir_camera = < 0.00, 5.00, 3.00 >;
#declare dist_camera = 25.0;
#declare intens_luz = 1.25;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)