// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2010-03-04 15:44:01 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_verde = 
  texture{
    pigment{ color rgb < 0, 1, 0 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio_tronco = 0.300;

#declare cedula = 
  box{ <-0.1,-0.2,0>, <+0.1,+0.2,0> }

// Partes da arvore

#declare tronco = 
cylinder
    {
        <0,0,0>, <0,0,5>,
        raio_tronco
	texture{ tx_fosca }
    }

#declare bico_tronco =
cone{
    
    <0, 0, 5>, raio_tronco,
    <0, 0, 6>, 0.1 * raio_tronco
    texture{ tx_fosca }
  }

// ======================================================================
// MACRO FOR THE TREE

#declare raio_cabeca = 0.5;
#declare raio_chapeu = 1;

#declare largura_membro = 1;
#declare abertura_perna = 0.2;
#declare largura_corpo  = 2*largura_membro + abertura_perna;

#declare tamanho_pe = 2;
#declare tamanho_anteperna = 3;
#declare tamanho_perna = 4;

#macro cabeca()
  union{
  
    // cabeca
    sphere {
      <0, 0, raio_cabeca>, // center
      raio_cabeca // radius
      texture{ tx_fosca }
    }
    
    // chapeu
    cylinder
    {
        <0, 0, raio_cabeca + 0.1>, <0, 0, raio_cabeca + 0.2>,
        raio_chapeu
	texture{ tx_fosca }
    }
    
  }
#end

#macro eixo_membro()
  union {
    // eixo
    cylinder
    {
      <+largura_membro/2, 0, 0>, <-largura_membro/2, 0, 0>,
      largura_membro/2
      texture{ tx_fosca }
    }
    
    // rolamento
    cylinder
    {
      <+largura_membro/2 + 0.1, 0, 0>, <-largura_membro/2 - 0.1, 0, 0>,
      largura_membro/3
      texture{ tx_verde }
    }
  }
#end

#macro membro_ponta(tamanho)
  union{

    // primeira articulacao
    object {eixo_membro()}

    // membro
    box {
        <+largura_membro/2, 0, -largura_membro/2>, <-largura_membro/2, tamanho, largura_membro/2>
        texture{ tx_fosca }
    }
    
    // eixo
    cylinder
    {
      <+largura_membro/2, +tamanho, 0>, <-largura_membro/2, +tamanho, 0>,
      largura_membro/2
      texture{ tx_fosca }
    }
  }
#end

#macro membro(tamanho)
  
  union{

    // primeira articulacao
    object {eixo_membro()}

    // membro
    box {
        <+largura_membro/2, 0, -largura_membro/2>, <-largura_membro/2, tamanho, largura_membro/2>
        texture{ tx_fosca }
    }
    
    // segunda articulacao
    object {eixo_membro() translate <0, tamanho, 0>}
  }
#end

// controla rotacao do pe
#macro anteperna(anglo_pe)
  
  union {
    // anteperna
    object { membro(tamanho_anteperna) rotate <-90, 0, 90> }
    
    // pe
    object{ membro_ponta(tamanho_pe) rotate<anglo_pe, 0, -90> translate <0, 0, -tamanho_anteperna>}
  }
#end

// controla rotacao da anteperna
#macro perna(anglo_anteperna, anglo_pe)
  
  union {
  
    // perna
    object { membro(tamanho_perna) rotate <-90, 0, 90> }
  
    // anteperna
    object { anteperna(anglo_pe) rotate <0, anglo_anteperna, 0> translate <0, 0, -tamanho_perna>}
  }
#end

#macro antebraco(anglo_mao)
  object{anteperna(-90 + anglo_mao) rotate <0, -90, 90>}
#end

#macro braco(anglo_antebraco, anglo_mao)
  object{perna(anglo_antebraco, -90 + anglo_mao) rotate <0, -90, 90>}
#end

#macro corpo(tamanho, anglo_perna_esquerda, anglo_anteperna_esquerda, anglo_pe_esquerdo,
		      anglo_perna_direita, anglo_anteperna_direita, anglo_pe_direito,
		      anglo_braco_esquerdo, anglo_antebraco_esquerdo, anglo_mao_esquerda,
		      anglo_braco_direito, anglo_antebraco_direito, anglo_mao_direita)
  
  union{

    // ombro esquerdo
    object {eixo_membro() translate <0, (largura_membro + abertura_perna)/2, 0>}
    // ombro direito
    object {eixo_membro() translate <0, -(largura_membro + abertura_perna)/2, 0>}
    
    //  ligacao_ombros
    box {
        <+largura_membro/2, -largura_corpo/2 + largura_membro/2, 0>, <-largura_membro/2, largura_corpo/2 - largura_membro/2, largura_membro/2>
        texture{ tx_fosca }
    }

    // corpo
    box {
        <+largura_membro/2, -largura_corpo/2, -tamanho>, <-largura_membro/2, largura_corpo/2, 0>
        texture{ tx_fosca }
    }
    
    // nadega esquerda
    object {eixo_membro() rotate <0, 0, 90> translate <0, (largura_membro + abertura_perna)/2, -tamanho>}
    // nadega direita
    object {eixo_membro() rotate <0, 0, 90> translate <0, -(largura_membro + abertura_perna)/2, -tamanho>}
    
    // perna direita
    object {perna(anglo_anteperna_esquerda, anglo_pe_esquerdo) rotate <0, anglo_perna_esquerda, 0> translate <0, -(largura_membro + abertura_perna)/2, -tamanho>}
    
    // perna esquerda
    object {perna(anglo_anteperna_direita, anglo_pe_direito) rotate <0, anglo_perna_direita, 0> translate <0, (largura_membro + abertura_perna)/2, -tamanho>}
    
    // braco esquerdo
    object {braco(anglo_antebraco_esquerdo, anglo_mao_esquerda) rotate <0, 0, 0> translate <0,  -(largura_membro + abertura_perna)/2, 0>}
    
    // braco direito
    object {braco(anglo_antebraco_direito, anglo_mao_direita) rotate <-180, 0, 0> translate <0,  (largura_membro + abertura_perna)/2, 0>}
    
    // cabeca
    object {cabeca() /*translate <0, 0, raio_cabeca>*/ scale 4}
  }
#end

#include "eixos.inc"

union{
  object{ eixos(5.00) }
  
  //object{ cabeca() }
  //object{ membro(3)}
  //object{ corpo(2)}
  //object{ eixo_membro()}
  //object{ membro_ponta(1)}
  //object{anteperna(15) scale 0.5}
  //object{perna(0, 0) scale 0.3}
  //object{antebraco(15) scale 0.5}
  //object{braco(0, 0) scale 0.3}
  object{ corpo(3, -45, 45, 45, 60, 45, 0, 0, -45, 0, 0, 0, -15) scale 0.2}
  
  object{ corpo(3, 45, 45, 45, -60, 45, 0, 0, 0, 15, 0, 45, 0) scale 0.2 translate <0, 3, 0>}
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 9.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 16.0;
#declare intens_luz = 1.00;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)